ABAP - SALV教程05 添加页眉和页脚

HeathlX2024-03-03 12:01

  • 先看看效果叭

  • CL_SALV_TABLE提供了SET_TOP_OF_LIST方法设置页眉显示和SET_TOP_OF_LIST_PRINT方法设置页眉打印来实现添加页眉的目的。

  • CL_SALV_TABLE提供了SET_END_OF_LIST方法设置页脚显示和SET_END_OF_LIST_PRINT方法设置页脚打印来实现添加页脚的目的。

  • 这个四个方法的传入参数为 CL_SALV_FORM_LAYOUT_GRID****类型，这是个类。

  • 实现步骤

  • 定义两个私有方法；SET_TOPPAGE:添加页眉，SET_ENDPAGE:添加页脚

    复制代码 
      PRIVATE SECTION.

    METHODS:
      set_toppage CHANGING co_alv TYPE REF TO cl_salv_table.

    METHODS:
      set_endpage CHANGING co_alv TYPE REF TO cl_salv_table.

  METHOD set_toppage.

    DATA: lo_h_label TYPE REF TO cl_salv_form_label,
          lo_h_flow  TYPE REF TO cl_salv_form_layout_flow.

    DATA(lo_header) = NEW cl_salv_form_layout_grid( ).

*   通过Row 和 column字段定位在top of page的文本输出位置
*   粗体 第一行第一列
    lo_h_label = lo_header->create_label( row = 1 column = 1 ).
    lo_h_label->set_text( 'Sale Orders of Report' ).

*   第二行第一列
    lo_h_flow = lo_header->create_flow( row = 2  column = 1 ).
    lo_h_flow->create_text( text = 'Create By:' && sy-uname ).

*   第三行第一列
    lo_h_flow = lo_header->create_flow( row = 3  column = 1 ).
    lo_h_flow->create_text( text = 'Number of Records in the output' ).

*   第三行第二列
    lo_h_flow = lo_header->create_flow( row = 3  column = 2 ).
    lo_h_flow->create_text( text = '20' ).

*   页眉显示
    co_alv->set_top_of_list( lo_header ).
*   页眉打印
    co_alv->set_top_of_list_print( lo_header ).
  ENDMETHOD.

  METHOD set_endpage.

    DATA: lo_f_label TYPE REF TO cl_salv_form_label,
          lo_f_flow  TYPE REF TO cl_salv_form_layout_flow.

    DATA(lo_footer) = NEW cl_salv_form_layout_grid( ).

*   通过Row 和 column字段定位在top of page的文本输出位置
*   粗体 第一行第一列
    lo_f_label = lo_footer->create_label( row = 1 column = 1 ).
    lo_f_label->set_text( 'Bilibili University' ).

*   第二行第一列
    lo_f_flow = lo_footer->create_flow( row = 2  column = 1 ).
    lo_f_flow->create_text( text = 'Date:' && sy-datum ).

*
    lo_f_flow = lo_footer->create_flow( row = 3  column = 1 ).
    lo_f_flow->create_text( text = 'Footer number' ).
*
    lo_f_flow = lo_footer->create_flow( row = 3  column = 2 ).
    lo_f_flow->create_text( text = 1 ).

*   页眉打印
    co_alv->set_end_of_list( lo_footer ).
*   页脚打印
    co_alv->set_end_of_list_print( lo_footer ).

  ENDMETHOD.

  • 同样的也是在创建SALV实例对象后调用方法

    复制代码 
        TRY.
        cl_salv_table=>factory(
          IMPORTING
            r_salv_table = mo_salv
          CHANGING
            t_table      = mt_data ).
      CATCH cx_salv_msg INTO DATA(lx_msg).
    ENDTRY.

    me->set_toppage( CHANGING co_alv = mo_salv ).
    me->set_endpage( CHANGING co_alv = mo_salv ).

  • 完整代码

    复制代码 
    CLASS lcl_model DEFINITION.
  PUBLIC SECTION.
    TYPES:BEGIN OF TY_dATA,
            vbeln TYPE vbak-vbeln,
            erdat TYPE erdat,
            erzet TYPE erzet,
            ernam TYPE ernam,
            auart TYPE auart.
    TYPES:END  OF ty_data.

    DATA mt_data TYPE TABLE OF ty_data.

    DATA mo_salv TYPE REF TO cl_salv_table.

    "获取数据的方法
    METHODS get_data.
    "展示SALV的方法
    METHODS alv_show.

  PRIVATE SECTION.
    METHODS:
      set_status  CHANGING co_alv TYPE REF TO cl_salv_table.

    METHODS:
      set_toppage CHANGING co_alv TYPE REF TO cl_salv_table.

    METHODS:
      set_endpage CHANGING co_alv TYPE REF TO cl_salv_table.

ENDCLASS.

CLASS lcl_model IMPLEMENTATION.
  METHOD get_data.
    SELECT vbeln erdat erzet ernam auart
      INTO TABLE mt_data
      FROM vbak
      UP TO 20 ROWS.
  ENDMETHOD.

  METHOD alv_show.
    TRY.
        cl_salv_table=>factory(
          IMPORTING
            r_salv_table = mo_salv
          CHANGING
            t_table      = mt_data ).
      CATCH cx_salv_msg INTO DATA(lx_msg).
    ENDTRY.
    me->set_status( CHANGING co_alv = mo_salv ).
    me->set_toppage( CHANGING co_alv = mo_salv ).
    me->set_endpage( CHANGING co_alv = mo_salv ).
    mo_salv->display( ).
  ENDMETHOD.

  METHOD set_status.
    DATA(lo_functions) = co_alv->get_functions( ).
    "cl_salv_functions_list类型的实例对象的添加状态方法
    lo_functions->set_all( abap_true ).
    "lo_functions->set_default( abap_true ).
  ENDMETHOD.

  METHOD set_toppage.

    DATA: lo_h_label TYPE REF TO cl_salv_form_label,
          lo_h_flow  TYPE REF TO cl_salv_form_layout_flow.

    DATA(lo_header) = NEW cl_salv_form_layout_grid( ).

*   通过Row 和 column字段定位在top of page的文本输出位置
*   粗体 第一行第一列
    lo_h_label = lo_header->create_label( row = 1 column = 1 ).
    lo_h_label->set_text( 'Sale Orders of Report' ).

*   第二行第一列
    lo_h_flow = lo_header->create_flow( row = 2  column = 1 ).
    lo_h_flow->create_text( text = 'Create By:' && sy-uname ).

*   第三行第一列
    lo_h_flow = lo_header->create_flow( row = 3  column = 1 ).
    lo_h_flow->create_text( text = 'Number of Records in the output' ).

*   第三行第二列
    lo_h_flow = lo_header->create_flow( row = 3  column = 2 ).
    lo_h_flow->create_text( text = '20' ).
*
*   页眉显示
    co_alv->set_top_of_list( lo_header ).
*
*   页眉打印
    co_alv->set_top_of_list_print( lo_header ).
  ENDMETHOD.

  METHOD set_endpage.

    DATA: lo_f_label TYPE REF TO cl_salv_form_label,
          lo_f_flow  TYPE REF TO cl_salv_form_layout_flow.

    DATA(lo_footer) = NEW cl_salv_form_layout_grid( ).

*   通过Row 和 column字段定位在top of page的文本输出位置
*   粗体 第一行第一列
    lo_f_label = lo_footer->create_label( row = 1 column = 1 ).
    lo_f_label->set_text( 'Bilibili University' ).

*   第二行第一列
    lo_f_flow = lo_footer->create_flow( row = 2  column = 1 ).
    lo_f_flow->create_text( text = 'Date:' && sy-datum ).

*
    lo_f_flow = lo_footer->create_flow( row = 3  column = 1 ).
    lo_f_flow->create_text( text = 'Footer number' ).
*
    lo_f_flow = lo_footer->create_flow( row = 3  column = 2 ).
    lo_f_flow->create_text( text = 1 ).

    co_alv->set_end_of_list( lo_footer ).
*   页脚打印
    co_alv->set_end_of_list_print( lo_footer ).

  ENDMETHOD.

ENDCLASS.

START-OF-SELECTION.
  DATA(lo_model) = NEW lcl_model( ).
  lo_model->get_data( ).
  lo_model->alv_show( ).
相关推荐
修电脑的猫3 天前
LSMW target field DATAM mapped as CHAR1, length 1 in table /SAPDMC/LSGBDC
sap·abap
duangww3 天前
ALV通过GOS服务实现上传PDF附件
abap·附件
爱喝水的鱼丶3 天前
SAP-ABAP：SAP表与视图权限管控方案：表维护权限、视图访问权限配置实操
运维·数据库·性能优化·sap·abap·权限·表和视图
爱喝水的鱼丶7 天前
SAP-ABAP：SAP视图开发入门：四类标准视图的适用场景与创建步骤详解
服务器·数据库·性能优化·sap·abap
爱喝水的鱼丶7 天前
SAP-ABAP：SAP多表连接视图实战：内连接/外连接配置逻辑与性能优化技巧
运维·开发语言·学习·性能优化·sap·abap
爱喝水的鱼丶13 天前
SAP-ABAP：SAP基础数据校验工具开发系列博客（共5篇）第五篇：性能优化与上线运维：保障高并发场景下的工具稳定运行
运维·学习·性能优化·sap·abap·erp·经验交流
爱喝水的鱼丶13 天前
SAP-ABAP：SAP 内存管理详解：从架构到优化
开发语言·学习·架构·sap·abap·内存管理
爱喝水的鱼丶15 天前
SAP-ABAP：SAP基础数据校验工具开发系列博客（共5篇）第三篇：SAP接口对接开发：实现数据的实时/批量校验交互
运维·数据库·学习·性能优化·sap·abap·经验交流
duangww15 天前
IDCNACCTBLN 增强实现负号提前
abap
爱喝水的鱼丶16 天前
SAP-ABAP:SAP 简单报表输出开发系列（共6篇） 第四篇：SAP 报表异常处理机制：数据校验与消息提示规范落地
开发语言·数据库·学习·算法·sap·abap
热门推荐
012026年6月AI行业全景：从百模大战到Agent元年，这30天发生了什么？022026年6月AI大模型全景报告：GPT-5.6、Claude Opus 4.8、Gemini 3.5，中美AI三足鼎立谁主沉浮？032026 年 AI 编程工具终极横评：Cursor vs Claude Code vs Copilot vs Windsurf04【AI】2026 年具身智能模型和世界模型总结05GitHub 镜像站点062026 AI 编程工具终极实战指南：Cursor vs Claude Code vs Copilot，开发者该怎么选？07AI科技热点日报 | 2026年6月1日08Codex 下载安装指南：Windows 和 macOS 官方版下载09上线仅72小时被强制下架：Claude Fable 5 的短命10AI一周事件 · 2026-06-03 至 2026-06-09