怎样将Word文档中脚注引用后面的空格轻松删除

最近将一份HTML文档转换成了Word文档，利用VBA将HTML文档中形如下面形式的注释转换成了脚注：

<sup class="notetext" data-note="巴西著名作家、政治家（1829------1877）。">📝</sup>

并将标题标签替换为对应的标题样式，最后用查找替换删除全部HTML标签，处理完成后，发现脚注引用标记后面都跟着一个空格，我个人并不喜欢这种空格，但是想要删除这些空格时遇到了问题：

1、不能用查找替换替换掉所有空格，因为文档中还有其他需要保留的空格；

2、如果先查找脚注引用和紧连着的空格，再用替换功能丢弃空格，经实际测试存在以下问题：

2.1、用脚注引用的字面文本 $0-9$ 无法匹配到脚注引用；

2.2、用符号"^f"加空格，可以匹配到脚注引用及后面的空格，但是符号"^f"不能填在替换为文本框中，无法通过替换丢掉空格；

2.3、先用符号"^f"加空格匹配到脚注引用及后面的空格，在替换为对话框中使用"^&#"，在空格后面增加一个#号，然后再查空格和#号替换为空来替换掉空格，第一步可以实现，但是替换的内容全部成了脚注引用，再用空格和#号查找时无法匹配。

看来只能用VBA解决问题。让deepseek生成了一个：

vbnet 复制代码

Sub 删除正文脚注引用后面的空格()
    Dim rng As Range
    Dim i As Long
    
    ' 遍历所有脚注引用区域
    For i = 1 To ActiveDocument.Footnotes.Count
        Set rng = ActiveDocument.Footnotes(i).Reference
        ' 将光标移动到引用标记末尾
        rng.Collapse Direction:=wdCollapseEnd
        ' 如果后面是空格，则删除
        If rng.Next = " " Then
            rng.Next.Delete
        End If
    Next i
End Sub

试一下，然并卵。自己搞算了：

vbnet 复制代码

Sub 删除正文脚注引用后面的空格()
    Dim rng As Range
    Dim i, j, k, l As Long
    j = 0: k = 0
     l = ActiveDocument.Footnotes.count
    Debug.Print "脚注总数：" & l
    
    ' 遍历所有脚注引用区域
    For i = 1 To l
        Set rng = ActiveDocument.Footnotes(i).Reference
        ' 将光标移动到引用标记末尾
        Selection.start = rng.End
        Selection.End = Selection.start + 1
        
        ' 如果后面是空格，则删除
        If Selection.text = " " Then
            Selection.Delete
            j = j + 1
        Else
            k = k + 1
        End If
    Next i
    Debug.Print "j = " & j & ", k = " & k
End Sub

自己搞的加了很多冗余的验证性质的代码，跟DeepSeek比一下，就知道真正有效的代码是哪些。

如果脚注引用后面的空格数量不确定，用下面这个宏可以不管空格数量的差别一次性全部删除，因此，推荐用下面这个兼容性更好的宏：

vbnet 复制代码

Sub 删除正文脚注引用后面的空格()
    Dim rng As Range, aFootnote As Footnote
    
    ' 遍历所有脚注引用区域
    For Each aFootnote In ActiveDocument.Footnotes
        Set rng = aFootnote.Reference
        ' 将光标移动到引用标记末尾
        Selection.Start = rng.End
        Selection.End = Selection.Start
        'Debug.Print Selection.Next().Text = " "
        
        ' 如果后面是连续空格，则使用Next方法定位并删除（Next方法会跳过单个空格）。
        ' Selection.Next默认参数为(unit:=wdCharacter, Count:=1)
        While Selection.Next().Text = " "
            Selection.Next().Delete
        Wend
        ' 如果后面是单个空格，则使用Selection.Characters(1)定位并删除删除
        If Selection.Characters(1).Text = " " Then Selection.Characters(1).Delete
    Next
End Sub

实测发现，Selection.Next()会跳过单个空格定位到后面的那个字符的Range，但不会跳过连续的多个空格，而Selection.Characters(1)则总是定位到光标后一个字符的Range，无论这个字符是不是空格。经测试，如果有连续三个空格，Selection.Next().Delete会执行两次，说明空格数量足够时执行一次会删除两个空格。