使用VBA快速比对数据

实例需求:第一行是全系列数据集合,现在需要对比第一行数据,查找第2行数据中缺失的数字,保存在第3行中。

具备VBA初步使用经验的同学,都可以使用双重循环实现这个需求,这里给大家提供另一种实现思路,如何快速找到这些缺失数字。

复制代码
Sub Demo()
    Dim res(), arrData1, arrData2
    Dim sNumlist, iCnt, iIdx, i
    arrData1 = Range([B1], [B1].End(xlToRight))
    arrData2 = Application.Transpose(Application.Transpose(Range([A2], [B2].End(xlToRight).Offset(0, 1))))
    sNumlist = Join(arrData2, "|")
    iCnt = UBound(arrData1, 2)
    ReDim res(0, 1 To iCnt)
    iIdx = 1
    For i = 1 To iCnt
        If InStr(1, sNumlist, "|" & arrData1(1, i) & "|", vbTextCompare) = 0 Then
            res(0, iIdx) = arrData1(1, i)
            iIdx = iIdx + 1
        End If
    Next
    [B3].Resize(1, iCnt).Value = res
End Sub

【代码解析】

第4行代码将工作表中第1行数据加载到数组中。

第5行代码将工作表中第2行数据加载到数组中,请注意与第4行的不同之处在于,数据区域从A列到最后一个数据(J列)之后一列(K列)结束,也就是数组中的第一个和最后一个元素都是空值。经过两次Transpose,使得结果为单维数组,便于后续代码进行合并。

第6行代码调用Join函数将数组arrData2合并为一个字符串,使用竖线作为分隔符,本示例中结果如下,由于第5代码中的特殊处理,使得此处获得了起始处和结尾处的竖线,而不需要使用字符串合并单独处理。

|7|8|9|10|1|2|14|15|6|

第7行代码获取数据的个数。

第8行代码创建动态数据保存结果。

第10~15行代码使用For循环结构查找数据。

第11行代码调用Instr查找对比数据,这里的小技巧在于:如何避免将数组14或者15中的十位数字匹配数字1。在被查找数字两侧增加竖线,也就是查找|1|,这就有效的避免了上述误判,并且不需要循环遍历数组进行逐个对比。

第12行代码将缺失数字保存在结果数组中。

第13行代码保存位置序号加一。

第16行代码将结果写入到工作表中。

相关推荐
YuCaiH3 天前
数组理论基础
笔记·leetcode·c·数组
刚入坑的新人编程7 天前
数据结构——栈和队列
c语言·数据结构·c++·链表·数组
carpell16 天前
【双指针法】:这么常用的你怎么能不知道
python·链表·字符串·数组·双指针法
梁辰兴19 天前
数据结构实验3.3:求解迷宫路径问题
数据结构·算法·深度优先·数组
Tisfy20 天前
LeetCode 3396.使数组元素互不相同所需的最少操作次数:O(n)一次倒序遍历
算法·leetcode·题解·数组·遍历·哈希表
知初~23 天前
集合与容器:List、HashMap(II)
java·链表·map·红黑树·数组·列表
podongfeng1 个月前
leetcode每日一题:数组美丽值求和
java·算法·leetcode·数组·前后缀
FAREWELL000751 个月前
C#基础学习(六)函数的变长参数和参数默认值
学习·c#·数组
琳沫lerlee1 个月前
【数组去重、分组和拷贝】
javascript·数组
我不是代码教父1 个月前
[原创](Modern C++)现代C++的关键性概念: array<>比内置数组更安全
c++·数组·array