汇编--int指令

中断信息可以来自CPU的内部和外部，当CPU的内部有需要处理的事情发生的时候，将产生需要马上处理的中断信息，引发中断过程。在http://t.csdn.cn/jihpG，我们讲解了中断过程和两种内中断的处理。

这一章中，我们讲解另一种重要的内中断，由int指令引发的中断。

int指令

int指令的格式为：int n

n为中断类型码，它的功能是引发中断过程。

CPU执行int n指令，相当于引发一个n号中断的中断过程，执行过程如下：

(1)取中断类型码n；

(2)标志寄存器入栈，IF=0，TF=0；

(3)CS、IP入栈；

(4)(IP)=(n*4)，(CS)=(n*4+2)

可以在程序中使用int指令调用任何一个中断的中断处理程序。例如，下面的程序：

这个程序在DOS方式下执行时，将在屏幕中间显示一个"!"，然后显示"Divide overflow"后返回到系统中。"!"是我们编程显示的，而"Divide overflow"是哪里来的呢?我们的程序中又没有做除法，不可能产生除法溢出。

程序是没有做除法，但是在结尾使用了int 0指令。CPU执行int 0指令时，将引发中断过程，执行0号中断处理程序，而系统设置的0号中断处理程序的功能是显示"Divide overflow"，然后返回到系统。

一般情况下，系统将一些具有一定功能的子程序，以中断处理程序的方式提供给应用程序调用。我们在编程的时候，可以用int指令调用这些子程序。当然，也可以自己编写一些中断处理程序供别人使用。以后，我们可以将中断处理程序简称为中断例程。

编写供应用程序调用的中断例程

前面，我们已经编写过中断0的中断例程了，现在我们讨论可以供应用程序调用的中断例程的编写方法。下面通过两个问题来讨论。

问题一：编写、安装中断7ch的中断例程。

功能：求一word型数据的平方。

参数：(ax)=要计算的数据。

返回值：dx、ax中存放结果的高16位和低16位。

应用举例：求：2*3456^2。

分析一下，我们要做以下3部分工作。

(1)编写实现求平方功能的程序；

(2)安装程序，将其安装在0：200处；

(3)设置中断向量表，将程序的入口地址保存在7ch表项中，使其成为中断7ch的中断例程。

安装程序如下：

复制代码

assume cs:code

code segment 
 start:  
	    ;安装sqr程序
		mov ax,cs 
		mov ds,ax
		mov si,offset sqr   ;设置ds:si指向源地址
		mov ax,0
		mov es,ax 
		mov di,200h   ;设置es:di指向目的地址
		mov cx,offset sqrend-offset sqr ;设置cx为传输长度
		cld         ;设置传输方向为正
		rep movsb
		
		;设置中断向量表
		mov ax,0
		mov es,ax 
		mov word ptr es:[7ch*4],200h 
		mov word ptr es:[7ch*4+2],0
		mov ax,4c00h 
		int 21h
		
	sqr:mul ax   ;求平方
		iret
		
 sqrend:nop
	       
	   
code ends
end start

注意，在中断例程sqr的最后，要使用iret指令。

用汇编语法描述， iret指令的功:

pop IP

pop cs

popf

CPU执行int 7ch指令进入中断例程之前，标志寄存器、当前的CS和IP被压入栈中，在执行完中断例程后，应该用iret指令恢复int 7ch执行前的标志寄存器和CS、IP的值，从而接着执行应用程序。

int指令和iret指令的配合使用与call指令和ret指令的配合使用具有相似的思路。

对int、iret和栈的深入理解

问题：用7ch中断例程完成loop指令的功能。

loop s的执行需要两个信息，循环次数和到s的位移，所以， 7ch中断例程要完成loop指令的功能，也需要这两个信息作为参数。我们用cx存放循环次数，用bx存放位移。

应用举例：在屏幕中间显示80个'!'

复制代码

assume cs:code

code segment 
 start:  
	    ;
		mov ax,0b800h 
		mov es,ax
		mov di,160*12+0
		mov bx,offset s-offset se ;计算从标号s到标号se的转移位移
		mov cx,80
	  s:mov byte ptr es:[di], '!'
		add di,2
		int 7ch   ;如果(cx)≠0，转移到标号s处,就是完成loop s的功能

	 se:nop
	
		mov ax,4c00h 
		int 21h
       
	   
code ends
end start

在上面的程序中，用int 7ch调用7ch中断例程进行转移，用bx传递转移的位移。

分析：为了模拟loop指令， 7ch中断例程应具备下面的功能:

(1)dec cx；

(2)如果(cx)≠0，转到标号s处执行，否则向下执行。

下面我们分析7ch中断例程如何实现到目的地址的转移。

(1)转到标号s显然应设(CS)=标号s的段地址，(IP)=标号s的偏移地址。

(2)那么，中断例程如何得到标号s的段地址和偏移地址呢?

int 7ch引发中断过程后，进入7ch中断例程，在中断过程中，当前的标志寄存器、CS和IP都要压栈，此时压入的CS和IP中的内容，分别是调用程序的段地址(可以认为是标号s的段地址) 和int 7ch后一条指令的偏移地址(即标号se的偏移地址) 。

可见，在中断例程中，可以从栈里取得标号s的段地址和标号se的偏移地址，而用标号se的偏移地址加上bx中存放的转移位移就可以得到标号s的偏移地址。

(3)现在知道，可以从栈中直接和间接地得到标号s的段地址和偏移地址，那么如何用它们设置CS：IP呢?

可以利用iret指令，我们将栈中的se的偏移地址加上bx中的转移位移，则栈中的se 的偏移地址就变为了s的偏移地址。我们再使用iret指令，用栈中的内容设置CS、IP，从而实现转移到标号s处。

7ch中断例程如下。

复制代码

      lp:push bp 
	     mov bp,sp 
		 dec cx 
		 jcxz lpret ;cx=0就转移
		 add[bp+2],bx ;产生中断时，pushf  push cs  push ip,进入中断程序后又push bp
		              ;(bp+2)就是se标号ip
					  ;(bp+2)加上位移bx就是s的偏移地址
					  ;之后iret过程中pop ip获取的就是s的偏移地址
   lpret:pop bp 
         iret