限制LitstBox控件显示指定行数的最新数据（2/3）

taller_20002023-10-16 16:18

实例需求：由于数据行数累加增加，控件加载的数据越来越多，每次用户都需要使用右侧滚动条拖动才能查看最新数据。

因此希望ListBox只加载最后10行数据（不含标题行），这样用户可以非常方便地选择数据，如下图所示。

上一篇博客已经实现了上图效果，美中不足的是需要借助辅助单元格区域，某些Excel洁癖的小伙伴会觉得不爽，工作表中多了一些非必要的数据，接下来就一起来看看如果不借助辅助单元格区域实现类似的效果。

限制LitstBox控件显示指定行数的最新数据（1/3）

示例代码如下。

Private Sub UserForm_Initialize()
    Dim arr(), lastRow As Long
    Dim j As Integer, i As Integer
    With ActiveSheet
        lastRow = .Cells(.Rows.Count, 1).End(xlUp).Row
        ReDim arr(IIf(lastRow > 10, 10, lastRow - 1), 2)
        For j = 1 To 3
            arr(0, j - 1) = .Cells(1, j).Text
        Next
        If lastRow > 10 Then
            For i = 1 To 10
                For j = 1 To 3
                    arr(i, j - 1) = .Cells(lastRow - 10 + i, j).Text
                Next
            Next
        Else
            For i = 1 To lastRow - 1
                For j = 1 To 3
                    arr(i, j - 1) = .Cells(i + 1, j).Text
                Next
            Next
        End If
    End With
    With Me.ListBox1
        .ColumnHeads = False
        .ColumnCount = 3
        .ColumnWidths = "75;75;75"
        .List = arr()
    End With
End Sub

【代码解析】

第5行代码获取最后数据行所在行号。

第6行代码为动态数组arr的分配存储空间，如果lastRow大于10，那么第一维下标范围为0~ 10;否则第一维下标范围为0~ lastRow-1；第2维下标范围为0~2。

第7~9行代码加载数据标题行。

如果lastRow大于10，第11~ 15行代码加载10行数据;否则第17~18行代码加载全部数据。

第24~29行代码与上一篇博客完全相同，此处不再赘述。

效果如下图所示，首行数据模拟实现ListBox标题行，对比本文开头的插图，可以看出二者的区别：

真正列标题具备"边框线"，无法单独控制模拟实现的标题行的显示格式
用户可以选中下图中的标题行，因此在控件事件代码中需要增加异常处理