前言

智能开关技术调研之后，就立刻在网上买了相关的设备进行验证。由于缺乏物联网相关知识，从购买设备到实现功能的过程踩了不少坑。遂特此记录，希望能够为和我一样在物联网道路上摸索的小伙伴们提供一些参考。

遇到的坑

设备的坑

在买设备之前已经了解过，实现一个远程控制开关需要用到继电器和ESP8266，相关的远程控制代码需要一个烧录器烧到ESP8266芯片上。在某宝上一番了解后就在一家店铺购买一个继电器，一个ESP-01S模块，还有一个烧录器。

设备到手后立刻去安装开发环境准备开发，不出意外的话要出意外了。两个意外：

继电器连线端子的螺丝口太小了，宽度只有2mm（见图），一般家用的螺丝刀都没办法使用。
竟然没有连接继电器的线！！！这个属实没有想到。

于是乎，购买了2mm的一字螺丝刀和arduino uno开发板套件。

列一下设备清单：

一个ESP-01S模块。
一个ESP-01S专用继电器模块。
一把2mm的一字螺丝刀。
arduino uno开发板套件。

驱动的坑

在代码烧录的时候，报了个错A fatal esptool.py error occurred: Failed to write to target RAM (result was 0107)

大家都知道，新人在遇到问题的时候很懵逼的，根本无从下手。好在一位博友的解答下，问题才得以解决。@Grayson_Zheng

这个问题和烧录器芯片有关系，我按照教程安装的是cp210驱动。在博友的解答下，才得知我购买的烧录器芯片是CH9102F，这个型号大家可以在烧录器上看到。

不过芯片上的字体太小了，如果不是我这5.3的眼睛，根本看不清。

下载CH9102F驱动后，成功烧录。比个耶

搭建开发环境

基于ESP8266开发远程控制开关（有多种选择），需要搭建ESP8266开发环境以及开发工具，这里使用Arduino IDE作为开发工具。

Arduino + ESP8266 开发环境搭建网上一大堆，我这里就不多赘述了。

我是mac电脑，是跟着这个教程搭建的开发环境，大家可以参考一下。不过需要注意上面遇到的坑（驱动问题）。

实现远程控制开关

开发环境搭建完成后，就可以打开Arduino IDE使用C语言进行编程了，此时会看到setup() 和 loop() 这两个函数。

从软件开发的角度来看：

setup() 就相当于main函数，通常在程序启动时做一些初始化配置。这里可以理解成为：在硬件设备通电后立即执行一次。
loop() 则是在setup() 运行完后不断地循环运行。

代码编写

要实现远程控制，那么设备就需要联网，然后接收命令进行控制。

所以在setup() 中要做以下几件事：

连接Wi-Fi。
设置控制设备的端口（也叫数字引脚）。这里就是ESP-01S模块的GPIO0端口，最终会通过GPIO0来控制继电器是否通电。
设置设备的通讯方式。这里基于TCP协议和设备进行通讯。

c 复制代码

#include <ESP8266WiFi.h>

#define RELAY 0    // ESP-01S模块的GPIO0端口

const char *ssid = "WiFi SSID";    // 设备要连接的Wi-Fi名称
const char *password = "WiFi password";    // 设备要连接的Wi-Fi密码

WiFiServer server(80);

//硬件通电后自动执行一次
void setup()
{
    pinMode(RELAY, OUTPUT);    //设置GPIO0端口为输出模式
    digitalWrite(RELAY, LOW);    //初始化继电器为关闭状态  
    WiFi.begin(ssid, password); //进行WiFi连接
    server.begin();//启动一个Web服务器，监听80端口
}

到这里Web开发人员应该就很熟悉了。Web服务器启动成功后，就可以接收参数，然后根据参数对GPIO0端口进行高电压、低电压的输出，从而达到远程控制的效果。

这些代码在 loop() 进行编写，关键代码如下。

c 复制代码

//setup()执行完成后循环执行该函数
void loop()
{
    WiFiClient client = server.available();
    if (!client)
        return;
    String request = client.readStringUntil('\r');
    client.flush();
    if (request.indexOf("/RELAY=ON") != -1) {
        digitalWrite(RELAY, LOW);//低电压关闭
    }
    if (request.indexOf("/RELAY=OFF") != -1) {
        digitalWrite(RELAY, HIGH);//高电压通电
    }

}

完整的代码如下

c 复制代码

#include <ESP8266WiFi.h>

#define RELAY 0    //connected to GPIO0

const char *ssid = "xxx";    // Enter your router or WiFi SSID here
const char *password = "xxx";    // Enter your router or WiFi password here

WiFiServer server(80);

void setup()
{
    Serial.begin(115200);
    pinMode(RELAY, OUTPUT);    //Set GPIO0 to output mode.
    digitalWrite(RELAY, HIGH);    //Set the GPIO0 output level to high.

    /* Connect to the WiFi network. */
    Serial.println("");
    Serial.print("Conneting to ");
    Serial.println(ssid);
    WiFi.begin(ssid, password);

    while (WiFi.status() != WL_CONNECTED) {     // If the connection to WiFi fails, retry every 500 milliseconds.
        delay(500);
        Serial.print(".");
    }

    Serial.println("");
    Serial.println("WiFi connected.");

    /* Start the Server. */
    server.begin();
    Serial.println("Server started.");

    /* Output of the IP address. */
    Serial.print("Use this URL to connect: ");
    Serial.print("http://");
    Serial.print(WiFi.localIP());
    Serial.println("/");
}

void loop()
{
    /* Check whether a user has established a connection. */
    WiFiClient client = server.available();
    if (!client)
        return;

    /* Wait until the user sends data. */
    Serial.println("new client.");
    while (!client.available())
        delay(1);

    /* Reading the first line of the request. */
    String request = client.readStringUntil('\r');
    Serial.println(request);
    client.flush();

    /* Assignment of the request. */
    int value = HIGH;
    if (request.indexOf("/RELAY=ON") != -1) {
        Serial.println("RELAY=ON");
        digitalWrite(RELAY, LOW);
        value = LOW;
    }
    if (request.indexOf("/RELAY=OFF") != -1) {
        Serial.println("RELAY=OFF");
        digitalWrite(RELAY, HIGH);
        value = HIGH;
    }

    /* Return the answer. */
    client.println("HTTP/1.1 200 OK");
    client.println("Content-Type: text/html");
    client.println("");
    client.println("<!DOCTYPE HTML>");
    client.println("<html>");
    client.println("<meta name='viewport' content='width=device-width, inital-scale=1'>");
    client.println("<head><title>ESP8266 RELAY Control</title></head>");
    client.println("<style>");
    client.println("* {text-align: center; font-family: Conso-las;}");
    client.println("");
    client.println(".container {position: absolute; top: 45%;");
    client.println("left: 50%; transform: translateX(-50%) translateY(-50%);}");
    client.println("");
    client.println(".inner {font-size: 40px;}");
    client.println("");
    client.println("a {display: inline-block; width: 300px; height: 100px;");
    client.println("color: #FFFF00; background-color: #275C6B;");
    client.println("margin-top: 20px; padding: 10px 20px;");
    client.println("text-decoration: none; border-radius: 5px;");
    client.println("font-weight: 800; font-size: 70px;}");
    client.println("</style>");
    client.println("<div class='container'>");
    client.println("<div class='inner'>");
    client.print("RELAY if now: ");

    if (value == HIGH)
        client.print("OFF");
    else
        client.print("ON");

    client.println("<br>");
    client.println("<a href=\"/RELAY=OFF\">OFF</a>");
    client.println("<a href=\"/RELAY=ON\">ON</a>");
    client.println("<style>");
    client.println(".footer-text { font-size: 25px; }");
    client.println(".bold-text { font-weight: bold; }"); 
    client.println("</style>");
    client.println("<div class='footer'>");
    client.println("<p class='footer-text'>This software was written by <span class='bold-text'>Grayson Zheng</span>.</p>");
    client.println("</div>");
    client.println("</div>");
    client.println("</html>");
    client.println("");
}