Arduino+ESP8266+华为云物联网平台实现智能开关

前言

最近在做一个物联网项目,涉及到智能开关的开发。目前已经实现简单的TCP通信远程控制,但是考虑到后期的设备管理以及设备通信所需要的技术和服务器的维护成本,我决定将设备接入云平台。本文将详细阐述如何利用华为云的物联网平台(IoTDA)实现设备的云上管理与通信。

前提条件

准备工作

设备侧选择用MQTT协议,因为对(IoTDA)SDK的编译环境不太了解,这里通过API的方式接入华为云的物联网平台。

获取IoTDA接入信息

首先需要拿到两个信息:

  1. 华为云物联网平台的接入信息,也就是URL和PORT。接入信息通过下图可以看到。

  2. 华为云物联网平台的设备连接鉴权信息。可以参考设备连接鉴权 。简单来讲,就是通过注册设备时的设备ID和密钥生成设备连接鉴权所需的参数(ClientId、Username、Password)。生成参数的链接

安装代码库

其次,设备侧作为MQTT的客户端,需要编写相关代码。基于Arduino IDE开发,可以使用现成的库减少工作量。

  1. 安装PubSubClient库,用于连接和交互MQTT代理服务器(IoTDA)。
  2. 安装ArduinoJson库,用于解析和生成 JSON 数据。

功能实现

基于IoTDA平台实现智能开关,代码要实现以下功能:

  1. 设备进行WiFi连接与网络通信。
  2. 设备通过MQTT协议接入IoTDA平台。
  3. 设备接收IoTDA平台下发的消息。
  4. 设备根据消息执行相应的控制操作。

WiFi连接

c 复制代码
#include <ESP8266WiFi.h>  

const char* ssid = "xxx";   //wifi名称
const char* password = "xxx";  //wifi密码

void setup_wifi() {  
  delay(10);  
  // We start by connecting to WiFi  
  Serial.println();  
  Serial.print("Connecting to ");  
  Serial.println(ssid);  
  
  WiFi.begin(ssid, password);  
  
  while (WiFi.status() != WL_CONNECTED) {  
    delay(500);  
    Serial.print(".");  
  }  
  
  Serial.println("");  
  Serial.println("WiFi connected");  
  Serial.print("IP address: ");  
  Serial.println(WiFi.localIP());  
}

对以上的代码进行解释:

ESP8266WiFi.h 库提供了与 WiFi 网络连接相关的功能,WiFi.begin(ssid, password); 这行代码就可以自动连接WiFi。

接入IoTDA

设备要接入IoTDA,就需要上面准备的接入信息。在代码中定义如下:

c 复制代码
const char* mqttServer = "xxx.myhuaweicloud.com";  
const int mqttPort = 1883;  
const char* mqttClientId = "xxx";      
const char* mqttUser ="xxx";
const char* mqttPassword = "xxx";

#define deviceId "xxx"

#define mqttTopic "$oc/devices/" deviceId "/sys/messages/down"

mqttTopic是在接入成功后,设备侧订阅的Topic,用来接收平台下发的消息。更多的topic定义参考IoTDA平台预置的topic

接下来就需要通过PubSubClient库进行接入IoTDA平台了

c 复制代码
WiFiClient espClient;  
PubSubClient client(espClient);  

void reconnect() {    
  client.setServer(mqttServer, mqttPort);  
  client.setCallback(callback);  
  while (!client.connected()) {  
    Serial.println("Attempting MQTT connection...");  
    if (client.connect(mqttClientId, mqttUser, mqttPassword)) {  
      Serial.println("connected");  
      client.subscribe(mqttTopic);  
    } else {  
      Serial.print(client.state());
      delay(5000);  
    }  
  }  
}  

接收IoTDA消息&控制开关

client.connect 成功后会订阅Topic,当在IoTDA平台下发消息时,就会在 callback 函数进行 digitalWrite(RELAY_PIN, state); 控制开关了。

c 复制代码
void callback(char* topic, byte* payload, unsigned int length) {  
  StaticJsonDocument<128> doc;  
  DeserializationError error = deserializeJson(doc, payload);  
  if (error) {  
    Serial.print(F("deserializeJson() failed: "));  
    Serial.println(error.c_str());  
    return;  
  }  
  
  const char* stateKey = "state";  
  if (doc.containsKey(stateKey)) {  
    bool state = doc[stateKey];  
    digitalWrite(RELAY_PIN, state);  
    Serial.print("Switch state: ");  
    Serial.println(state ? "ON" : "OFF");  
  }  
}  
  

完整代码

c 复制代码
#include <ESP8266WiFi.h>  
#include <PubSubClient.h>  
#include <ArduinoJson.h>  
  
const char* ssid = "xxx";  
const char* password = "xxx.";  
const char* mqttServer = "xxx.myhuaweicloud.com";  
const int mqttPort = 1883;  
const char* mqttClientId = "xxx";      
const char* mqttUser ="xxx";
const char* mqttPassword = "xxx";

#define RELAY_PIN 0


#define deviceId "xxx"

#define mqttTopic "$oc/devices/" deviceId "/sys/messages/down"



WiFiClient espClient;  
PubSubClient client(espClient);  
  
void callback(char* topic, byte* payload, unsigned int length) {  
  StaticJsonDocument<128> doc;  
  DeserializationError error = deserializeJson(doc, payload);  
  if (error) {  
    Serial.print(F("deserializeJson() failed: "));  
    Serial.println(error.c_str());  
    return;  
  }  
  
  const char* stateKey = "state";  
  if (doc.containsKey(stateKey)) {  
    bool state = doc[stateKey];  
    digitalWrite(RELAY_PIN, state);  
    Serial.print("Switch state: ");  
    Serial.println(state ? "ON" : "OFF");  
  }  
}  
  
void reconnect() {  
  while (!client.connected()) {  
    Serial.println("Attempting MQTT connection...");  
    if (client.connect(mqttClientId, mqttUser, mqttPassword)) {  
      Serial.println("connected");  
      client.subscribe(mqttTopic);  
    } else {  
      Serial.print(client.state());
      delay(5000);  
    }  
  }  
}  
  
void setup_wifi() {  
  delay(10);  
  Serial.println();  
  Serial.print("Connecting to ");  
  Serial.println(ssid);  
  
  WiFi.begin(ssid, password);  
  
  while (WiFi.status() != WL_CONNECTED) {  
    delay(500);  
    Serial.print(".");  
  }  
  
  Serial.println("");  
  Serial.println("WiFi connected");  
  Serial.print("IP address: ");  
  Serial.println(WiFi.localIP());  
}  
  
void setup() {  
  Serial.begin(115200);  
  pinMode(RELAY_PIN, OUTPUT); 
  digitalWrite(RELAY_PIN, HIGH); 
  
  setup_wifi();  
  client.setServer(mqttServer, mqttPort);  
  client.setCallback(callback);  
}  
  
void loop() {  
  if (!client.connected()) {  
    reconnect();  
  }  
  client.loop();  
}

IoTDA平台下发消息

将编写完成的代码烧录到ESP-01S模块后,就可以通过IoTDA平台进行消息下发了。消息下发位置见下图

消息下发格式:

json 复制代码
{
    "state":true
}

statetrue时,表示电平状态为HIGH,电路呈开启状态,此时电路不通电。

而当statefalse时,电平状态则为LOW,电路闭合,此时电路处于通电状态。

通过state数值的变化,从而达到远程控制开关。

问题记录

在串口调试时,如果mqtt连接返回-1状态码,意味着连接失败。

那么需要将 PubSubClient.h 库中的两个宏定义MQTT_KEEPALIVEMQTT_MAX_PACKET_SIZE 的数值调大。本文中的代码已分别调整为60和2048。

总结

借助华为云的物联网平台IoTDA,可以帮助物联网行业的用户快速完成设备联网及行业应用集成,大大提高了开发人员的工作效率。而且按需计费每月前一百万条消息是免费的,很大程度上降低了设备上云的成本。

相关推荐
小赖同学啊2 小时前
物联网统一网关:多协议转换与数据处理架构设计
物联网
乌恩大侠7 小时前
60G毫米波雷达树莓派扩展板
物联网·5g·树莓派·雷达·树莓派扩展板
未来之窗软件服务11 小时前
智能 IOT 设备管理系统的设计与实现 —— 从管理及售后维护视角——毕业论文——东方仙盟
物联网·仙盟创梦ide·东方仙盟
糖糖单片机设计1 天前
硬件开发_基于STM32单片机的电脑底座系统
stm32·单片机·嵌入式硬件·物联网·51单片机
蓝蜂物联网2 天前
边缘计算网关赋能智慧农业:物联网边缘计算的创新应用与实践
人工智能·物联网·边缘计算
TDengine (老段)2 天前
TDengine 转化类函数 TO_CHAR 用户手册
大数据·数据库·物联网·时序数据库·tdengine·涛思数据
蓝蜂物联网2 天前
边缘计算网关与 EMCP 物联网云平台:无缝协作,共筑智能生态
人工智能·物联网·边缘计算
远创智控研发五部2 天前
C200H以太网通道服务监控、人机交互与驱动
物联网·数据采集·以太网模块·工业自动化·欧姆龙plc
绿蕉2 天前
中国5G RedCap基站开通情况及2025年全年计划
物联网·5g redcap·蜂窝通讯
Gauss松鼠会2 天前
华为云DRS实现Oracle到GaussDB数据库迁移的全流程技术方案
数据库·sql·安全·华为云·database·gaussdb