【Ardiuno】实验ESP32单片机搭建简易Web服务器功能(图文)

今天,小飞鱼继续来测试使用ESP32来实现简易的wifi无线web服务器功能。使用Ardiuno平台编辑器输入以下示例代码:

复制代码
#include <WiFi.h>
#include <WiFiClient.h>
#include <WebServer.h>
#include <ESPmDNS.h>

const char* ssid = "XIAOFEIYU";
const char* password = "XIAOFEIYU666";

WebServer server(80);

const int led = 13;

void handleRoot() {
  digitalWrite(led, 1);
  server.send(200, "text/plain", "Hello from ESP32! --- XIAOFEIYU");
  digitalWrite(led, 0);
}

void handleNotFound() {
  digitalWrite(led, 1);
  String message = "File Not Found\n\n";
  message += "URI: ";
  message += server.uri();
  message += "\nMethod: ";
  message += (server.method() == HTTP_GET) ? "GET" : "POST";
  message += "\nArguments: ";
  message += server.args();
  message += "\n";
  for (uint8_t i = 0; i < server.args(); i++) {
    message += " " + server.argName(i) + ": " + server.arg(i) + "\n";
  }
  server.send(404, "text/plain", message);
  digitalWrite(led, 0);
}

void setup(void) {
  pinMode(led, OUTPUT);
  digitalWrite(led, 0);
  Serial.begin(9600);
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  Serial.println("");

  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  if (MDNS.begin("esp32")) {
    Serial.println("MDNS responder started");
  }

  server.on("/", handleRoot);

  server.on("/inline", []() {
    server.send(200, "text/plain", "this works as well");
  });

  server.onNotFound(handleNotFound);

  server.begin();
  Serial.println("HTTP server started");
}

void loop(void) {
  server.handleClient();
  delay(2); 
}

编译上传程序到ESP32开发板,查看串口监视器输出,得到开发板获取的ip地址

打开浏览器,输入开发板连接wifi获取的ip地址,可以看到有网页内容显示出来,我们的简易web服务器可以工作了。

可以输入指定的参数,显示预设的内容:

输入其他路径,如果没有这个地址设置,则显示找不到文件。

通过以上示例代码的实验,我们了解了使用ESP32搭建web服务器的过程和web服务器的使用方法,积累了相关开发经验,继续Go。

相关推荐
christine-rr14 小时前
linux常用命令(4)——压缩命令
linux·服务器·redis
東雪蓮☆14 小时前
深入理解 LVS-DR 模式与 Keepalived 高可用集群
linux·运维·服务器·lvs
乌萨奇也要立志学C++15 小时前
【Linux】进程概念(二):进程查看与 fork 初探
linux·运维·服务器
绿箭柠檬茶16 小时前
Ubuntu 服务器配置转发网络访问
服务器·网络·ubuntu
獭.獭.16 小时前
Linux -- 信号【上】
linux·运维·服务器
路由侠内网穿透18 小时前
本地部署 GPS 跟踪系统 Traccar 并实现外部访问
运维·服务器·网络·windows·tcp/ip
ZERO_pan20 小时前
服务器装机遇到的问题
运维·服务器
l1t20 小时前
利用DeepSeek实现服务器客户端模式的DuckDB原型
服务器·c语言·数据库·人工智能·postgresql·协议·duckdb
杀气丶21 小时前
Linux下运行芙蕾雅天堂2【俄文简译L2FATER】
运维·服务器·天堂2·l2fater·l2fater.cn
喵手21 小时前
玩转Java网络编程:基于Socket的服务器和客户端开发!
java·服务器·网络