EmguCV学习笔记 VB.Net 2.S 特别示例

VB.Net2024-08-18 22:03

版权声明：本文为博主原创文章，转载请在显著位置标明本文出处以及作者网名，未经作者允许不得用于商业目的。
教程VB.net版本请访问： EmguCV学习笔记 VB.Net 目录-CSDN博客

教程C#版本请访问： EmguCV学习笔记 C# 目录-CSDN博客

笔者的博客网址：VB.Net-CSDN博客****

教程配套文件及相关说明以及如何获得pdf教程和代码（博客上的教程内容会和pdf教程一致，教程中也会包含所有代码），请移步：EmguCV学习笔记****

2.S 特别示例

本节示例参考**《计算机视觉** 40 例从入门到深度学习（OpenCV-Python ）》。

2.S.1 生成随机值图像

随机值图像，即每个像素的颜色随机的图像。本节内容介绍了三种方式生成随机值图像。

1、通常的方式

直接使图像每个像素点的颜色为随机颜色。

【代码位置：frmChapter2_S1】Button1_Click

'生成随机值图像1

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

'使用Matrix来生成灰度（单通道）的随机值图像

Dim s As New Size(400, 400)

Dim matr As New Matrix(Of Byte)(s)

Dim r As New Random()

For i As Integer = 0 To s.Width - 1

For j As Integer = 0 To s.Height - 1

matr(i, j) = r.Next(256)

Next

Next

ImageBox1.Image = matr.Mat

'使用Image来生成彩色（多通道）的随机值图像

Dim img As New Image(Of Bgr, Byte)(s)

Dim r2 As New Random()

For i As Integer = 0 To s.Width - 1

For j As Integer = 0 To s.Height - 1

img(i, j) = New Bgr(r2.Next(256), r2.Next(256), r2.Next(256))

Next

Next

ImageBox2.Image = img.Mat

End Sub

运行后如下图所示：

图2-84 普通方法生成随机噪声图片

2、SetRandNormal

Matrix类的SetRandNormal方法用于将矩阵的每个元素设置为正态分布随机数。SetRandNormal方法的具体使用参看2.2.6节【随机矩阵】。

【代码位置：frmChapter2_S1】Button2_Click

'生成随机值图像2 SetRandNormal

Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click

Dim matr As New Matrix(Of Byte)(New Size(400, 400))

matr.SetRandNormal(New MCvScalar(100), New MCvScalar(200))

Dim m As New Mat

m = matr.Mat

ImageBox1.Image = m

Dim matr1 As New Matrix(Of Byte)(400, 400, 3)

matr1.SetRandNormal(New MCvScalar(100, 100, 100), New MCvScalar(200, 200, 200))

Dim m1 As New Mat

m1 = matr1.Mat

ImageBox2.Image = m1

End Sub

运行后如下图所示：

图2-85 SetRandNormal方法生成随机噪声图片

3、SetRandUniform

Matrix类的SetRandUniform方法用于将矩阵的每个元素设置为均匀分布的随机数，要设置随机数的Matrix对象可以是单通道矩阵或多通道矩阵。该方法声明如下：

Public Sub SetRandUniform (

floorValue As MCvScalar,

ceilingValue As MCvScalar

)

参数说明：

  1. floorValue：随机数范围的下界（获取的值包含此下界）。
  2. ceilingValue：随机数范围的上界（获取的值不包含此上界）。

【代码位置：frmChapter2_S1】Button3_Click

'生成随机值图像3 SetRandUniform

Private Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click

Dim matr As New Matrix(Of Byte)(New Size(400, 400))

matr.SetRandUniform(New MCvScalar(100), New MCvScalar(200))

Dim m As New Mat

m = matr.Mat

ImageBox1.Image = m

Dim matr1 As New Matrix(Of Byte)(400, 400, 3)

matr1.SetRandUniform(New MCvScalar(100, 100, 100), New MCvScalar(200, 200, 200))

Dim m1 As New Mat

m1 = matr1.Mat

ImageBox2.Image = m1

End Sub

运行后如下图所示：

图2-86 SetRandUniform方法生成随机噪声图像

2.S.2 图像加密

为了使读者更清楚掌握详细加解密过程，这里分为图像的整体加解密和图像的局部加解密，并附上详细操作步骤，请结合代码深入掌握。

一、图像整体加解密

具体实现步骤：

（一）准备

1、载入源图像（mSrc）

2、与源图像同等大小的随机值图像（mKey）

（二）加密

3、源图像（mSrc）和随机值图像（mKey）进行Xor操作，将源图像加密，生成加密图像（mEnc）。

（三）解密

4、加密图像（mEnc）和随机值图像（mKey）进行Xor操作，将加密图像解密，生成解密图像（mDec）。

以下是详细的代码实现：

【代码位置：frmChapter2_S1】Button4_Click

'图像加密和解密

Private Sub Button4_Click(sender As Object, e As EventArgs) Handles Button4.Click

Dim mSrc As New Mat("c:\lessons\lena.jpg", ImreadModes.Color)

Dim mKey As New Mat

'生成三通道随机值图像

Dim matr1 As New Matrix(Of Byte)(mSrc.Rows, mSrc.Cols, 3)

matr1.SetRandNormal(New MCvScalar(0, 0, 0), New MCvScalar(255, 255, 255))

mKey = matr1.Mat

'显示密钥图像

ImageBox1.Image = mKey

'加密

Dim mEnc As New Mat()

CvInvoke.BitwiseXor(mSrc, mKey, mEnc)

'显示加密图像

ImageBox2.Image = mEnc

'解密

Dim mDec As New Mat

CvInvoke.BitwiseXor(mEnc, mKey, mDec)

'显示解密图像

ImageBox3.Image = mDec

End Sub

运行后如下图所示：

图2-87 图像整体加解密

二、三种方式生成加密图像的对比

为了更进一步地做好图像局部加解密，笔者这里将2.S.1节【生成随机值图像】的三种方法做成了函数，只需要输入图像大小就可以生成对应大小的随机值图像。具体代码如下：

【代码位置：frmChapter2_S1】getRandCh3、getRandNormalCh3、getRandUniformCh3

'普通方式生成三通道随机值图像

Private Function getRandCh3(ByVal s As Size) As Mat

Dim img As New Image(Of Bgr, Byte)(s)

Dim r As New Random()

For i As Integer = 0 To s.Width - 1

For j As Integer = 0 To s.Height - 1

img(i, j) = New Bgr(r.Next(256), r.Next(256), r.Next(256))

Next

Next

Return img.Mat

End Function

'SetRandNormal生成三通道随机值图像

Private Function getRandNormalCh3(ByVal s As Size) As Mat

Dim matr As New Matrix(Of Byte)(s.Height, s.Width, 3)

matr.SetRandNormal(New MCvScalar(0, 0, 0), New MCvScalar(255, 255, 255))

Return matr.Mat

End Function

'SetRandUniform生成三通道随机值图片

Private Function getRandUniformCh3(ByVal s As Size) As Mat

Dim matr As New Matrix(Of Byte)(s.Height, s.Width, 3)

matr.SetRandUniform(New MCvScalar(0, 0, 0), New MCvScalar(255, 255, 255))

Return matr.Mat

End Function

使用以上三个函数对图像加密实现代码如下：

【代码位置：frmChapter2_S1】Button5_Click

'三种方式生成随机图像进行加密

Private Sub Button5_Click(sender As Object, e As EventArgs) Handles Button5.Click

Dim mSrc As New Mat("C:\learnEmgucv\lena.jpg", ImreadModes.Color)

'加密1

Dim mKey1 As New Mat

mKey1 = getRandCh3(mSrc.Size)

Dim mEnc1 As New Mat()

mEnc1 = mSrc.Clone

CvInvoke.BitwiseXor(mSrc, mKey1, mEnc1)

ImageBox1.Image = mEnc1

'加密2

Dim mKey2 As New Mat

mKey2 = getRandNormalCh3(mSrc.Size)

Dim mEnc2 As New Mat()

CvInvoke.BitwiseXor(mSrc, mKey2, mEnc2)

ImageBox2.Image = mEnc2

'加密3

Dim mKey3 As New Mat

mKey3 = getRandUniformCh3(mSrc.Size)

Dim mEnc3 As New Mat()

CvInvoke.BitwiseXor(mSrc, mKey3, mEnc3)

ImageBox3.Image = mEnc3

End Sub

运行后如下图所示：

图2-88 三种方式生成加密图像

可以看到中间图像加密后隐约能够看到源图像的样子，而其它两种方式能够很好地对图像加密。采用SetRandNormal方式生成的随机值图像，由于使用了正态分布，作为加密方式不理想。

三、图像局部加解密

具体实现步骤：

（一）准备

1、载入源图像（mSrc）

2、生成背景黑色，区域白色的掩码图像1（mMask1）

3、生成背景白色，区域黑色的掩码图像2（mMask2）

4、生成密钥图像（mKey）

（二）加密

5、密钥图像（mKey）和源图像（mSrc）进行Xor操作，将源图像加密，生成加密图像（mEnc）。图2-SA1 第1张图。

6、将加密图像（mEnc）和掩码图像1（mMask1）进行And操作，生成背景黑色+区域加密图像1（mEncPart）。图2-SA1 第2张图。

7、将源图像（mSrc）和掩码图像2（mMask2）进行And操作，生成背景不加密+区域黑色图像2（mnoEncPart）。图2-SA1 第3张图。

8、将加密图像1（mEncPart）和黑色图像2（mnoEncPart）进行直接相加，去除黑色部分，生成背景不加密+区域加密的最终图像（mResult）。图2-SA1 第4张图。

图2-89 加密过程

（三）解密

9、将最终图像（mResult）和密钥图像（mKey）进行Xor操作，生成背景加密+区域解密图像1（mDecPart）。图2-SA2 第1张图。

10、将解密图像1（mDecPart）和掩码图像1（mMask1）进行And操作，生成背景黑色+区域解密图像2（monlyDecPart）。图2-SA2 第2张图。

11、将最终图像（mResult）和掩码图像2（mMask2）进行And操作，生成背景不加密+区域黑色图像（mnoDecPart）。图2-SA2 第3张图。

12、将解密图像2（monlyDecPart）和黑色图像（mnoDecPart）进行直接相加，去除黑色部分，生成生成解密图像（mDecResult）。图2-SA1 第4张图。

图2-90 解密过程

以下是详细的代码实现：

【代码位置：frmChapter2_S1】Button6_Click

'图像局部加密和解密

Private Sub Button6_Click(sender As Object, e As EventArgs) Handles Button6.Click

Dim mSrc As New Mat("C:\learnEmgucv\lena.jpg", ImreadModes.Color)

ImageBox1.Image = mSrc

'对(200,200,399,399）区域进行加密解密

'生成背景黑色，区域白色的掩码图像1

Dim mMask1 As New Mat(mSrc.Size, DepthType.Cv8U, 3)

mMask1.SetTo(New MCvScalar(0, 0, 0))

Dim mMask1RIO As New Mat(mMask1, New Rectangle(200, 200, 200, 200))

mMask1RIO.SetTo(New MCvScalar(255, 255, 255))

'生成背景白色，区域黑色的掩码图像2

Dim mMask2 As New Mat(mSrc.Size, DepthType.Cv8U, 3)

mMask2.SetTo(New MCvScalar(255, 255, 255))

Dim mMask2RIO As New Mat(mMask2, New Rectangle(200, 200, 200, 200))

mMask2RIO.SetTo(New MCvScalar(0, 0, 0))

'Key图像

Dim mKey As New Mat

mKey = getRandUniformCh3(mSrc.Size)

'加密

Dim mEnc As New Mat

'Xor 将源图像全加密

CvInvoke.BitwiseXor(mSrc, mKey, mEnc)

Dim mEncPart As New Mat

'And 生成背景黑色+区域加密图像1

CvInvoke.BitwiseAnd(mEnc, mMask1, mEncPart)

Dim mnoEncPart As New Mat

'And 生成背景不加密+区域黑色图像2

CvInvoke.BitwiseAnd(mSrc, mMask2, mnoEncPart)

Dim mResult As New Mat

mResult = mEncPart + mnoEncPart

'相加，去除黑色部分，生成背景不加密+区域加密的最终图像

ImageBox2.Image = mResult

'解密

Dim mDecPart As New Mat

'Xor 生成背景加密+区域解密图像1

CvInvoke.BitwiseXor(mResult, mKey, mDecPart)

Dim monlyDecPart As New Mat

'And 生成背景黑色+区域解密图像2

CvInvoke.BitwiseAnd(mDecPart, mMask1, monlyDecPart)

Dim mnoDecPart As New Mat

'And 生成背景不加密+区域黑色图像

CvInvoke.BitwiseAnd(mResult, mMask2, mnoDecPart)

Dim mDecResult As New Mat

'相加，生成解密图像

mDecResult = monlyDecPart + mnoDecPart

ImageBox3.Image = mDecResult

End Sub

运行后如下图所示：

图2-91 图像局部加解密

以上代码仅显示了加密解密结果，有兴趣的朋友可以将每一步生成的图像显示出来进一步了解加解密过程。

2.S.3 文字纹理

将文字图像生成0和255的二值化图像，使文字部分为黑色（根据实际情况需要考虑反色），然后将文字图像和纹理图像直接相加，文字图像黑色（值为0）的部分相加后为纹理图像的颜色，文字图像白色（值为255）的部分相加后保持白色（255）。具体实现代码如下：

【代码位置：frmChapter2_S2】Button1_Click

'灰度图像，以指定图像作为文字纹理

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

Dim msrc As New Mat("c:\learnEmgucv\lena.jpg", ImreadModes.Grayscale)

ImageBox1.Image = msrc

'文字文件

Dim mwatermark As New Mat("c:\learnEmgucv\watermark.jpg", ImreadModes.Grayscale)

ImageBox2.Image = mwatermark

Dim mmask As New Mat

'二值化并反色：将文字部分变为黑色0

CvInvoke.Threshold(mwatermark, mmask, 0, 255, ThresholdType.BinaryInv)

Dim result As New Mat

result = msrc + mmask

ImageBox3.Image = result

End Sub

运行后如下图所示：

图2-92 灰度图像的文字增加纹理

如果是彩色图像，那么先将三个通道分解出来，分别与文字的二值化图像相加，最后再合并。具体实现代码如下：

【代码位置：frmChapter2_S2】Button2_Click

'彩色图像，以指定图像作为文字纹理

Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click

Dim msrc As New Mat("c:\learnEmgucv\lena.jpg", ImreadModes.Color)

ImageBox1.Image = msrc

'文字文件

Dim mwatermark As New Mat("c:\learnEmgucv\watermark.jpg", ImreadModes.Grayscale)

ImageBox2.Image = mwatermark

Dim mmask As New Mat

'二值化并反色：将文字部分变为黑色0

CvInvoke.Threshold(mwatermark, mmask, 0, 255, ThresholdType.BinaryInv)

'分解每个通道

Dim mchanel3() As Mat

mchanel3 = msrc.Split()

'每个通道计算后再合并

Dim mv As New VectorOfMat

For i As Integer = 0 To mchanel3.Length - 1

Dim msingle As New Mat

msingle = mchanel3(i) + mmask

mv.Push(msingle)

Next

Dim result As New Mat

CvInvoke.Merge(mv, result)

ImageBox3.Image = result

End Sub

运行后如下图所示：

图2-93 彩色图像的文字增加纹理

2.S.4 图像水印

将水印文件二值化后，与源文件相加，即可得到相应的水印图像。具体实现代码如下：

【代码位置：frmChapter2_S2】Button3_Click

'图像水印

Private Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click

Dim msrc As New Mat("c:\learnEmgucv\lena.jpg", ImreadModes.Grayscale)

ImageBox1.Image = msrc

'水印文件，与源图像大小相同

Dim mwatermark As New Mat("c:\learnEmgucv\watermark.jpg", ImreadModes.Grayscale)

ImageBox2.Image = mwatermark

CvInvoke.Threshold(mwatermark, mwatermark, 0, 255, ThresholdType.Binary)

Dim mendwatermark As New Mat

'相加

'mwatermark为0的元素会将最后结果mendwatermark中对应位置的元素保持不变

'mwatermark为255的元素会将最后结果mendwatermark中对应位置的元素设置为255

mendwatermark = mwatermark + msrc

ImageBox3.Image = mendwatermark

End Sub

运行后如下图所示：

图2-94 图像增加水印

除了直接相加外，还可以指定水印图像和源图像的权重再相加。

【代码位置：frmChapter2_S2】Button4_Click

'图像水印

Private Sub Button4_Click(sender As Object, e As EventArgs) Handles Button4.Click

Dim msrc As New Mat("c:\learnEmgucv\lena.jpg", ImreadModes.Grayscale)

ImageBox1.Image = msrc

'水印文件，与源图像大小相同

Dim mwatermark As New Mat("c:\learnEmgucv\watermark.jpg", ImreadModes.Grayscale)

ImageBox2.Image = mwatermark

CvInvoke.Threshold(mwatermark, mwatermark, 0, 255, ThresholdType.Binary)

Dim mendwatermark As New Mat

'AddWeighted指定权重系数

Dim mendwatermark2 As New Mat

CvInvoke.AddWeighted(msrc, 0.4, mwatermark, 0.2, 0, mendwatermark2)

ImageBox3.Image = mendwatermark2

End Sub

运行后如下图所示：

图2-95 图像增加水印

彩色图像水印仍然采取分解图像通道，分别处理后再合并的做法：

【代码位置：frmChapter2_S2】Button5_Click

'彩色图像水印

Private Sub Button5_Click(sender As Object, e As EventArgs) Handles Button5.Click

Dim msrc As New Mat("c:\learnEmgucv\lena.jpg", ImreadModes.Color)

ImageBox1.Image = msrc

'水印文件，与源图像大小相同

Dim mwatermark As New Mat("c:\learnEmgucv\watermark.jpg", ImreadModes.Grayscale)

ImageBox2.Image = mwatermark

CvInvoke.Threshold(mwatermark, mwatermark, 0, 255, ThresholdType.Binary)

'分解每个通道

Dim mchanel3() As Mat

mchanel3 = msrc.Split()

'每个通道计算后再合并

Dim mv As New VectorOfMat

For i As Integer = 0 To mchanel3.Length - 1

Dim msingle As New Mat

msingle = mchanel3(i) + mwatermark

mv.Push(msingle)

Next

Dim result As New Mat

CvInvoke.Merge(mv, result)

ImageBox3.Image = result

End Sub

运行后如下图所示：

图2-96 彩色图像增加水印

相关推荐
可均可可31 分钟前
C++之OpenCV入门到提高004：Mat 对象的使用
c++·opencv·mat·imread·imwrite
蒙娜丽宁1 小时前
《Python OpenCV从菜鸟到高手》——零基础进阶，开启图像处理与计算机视觉的大门！
python·opencv·计算机视觉
好喜欢吃红柚子1 小时前
万字长文解读空间、通道注意力机制机制和超详细代码逐行分析（SE,CBAM,SGE,CA,ECA,TA）
人工智能·pytorch·python·计算机视觉·cnn
plmm烟酒僧2 小时前
Windows下QT调用MinGW编译的OpenCV
开发语言·windows·qt·opencv
AI小杨2 小时前
【车道线检测】一、传统车道线检测：基于霍夫变换的车道线检测史诗级详细教程
人工智能·opencv·计算机视觉·霍夫变换·车道线检测
冷凝女子3 小时前
【QT】海康视频及openCv抓拍正脸接口
qt·opencv·音视频·海康
撞南墙者5 小时前
OpenCV自学系列（1）——简介和GUI特征操作
人工智能·opencv·计算机视觉
王哈哈^_^5 小时前
【数据集】【YOLO】【VOC】目标检测数据集，查找数据集，yolo目标检测算法详细实战训练步骤！
人工智能·深度学习·算法·yolo·目标检测·计算机视觉·pyqt
柳鲲鹏6 小时前
OpenCV视频防抖源码及编译脚本
人工智能·opencv·计算机视觉
jndingxin6 小时前
OpenCV视觉分析之目标跟踪(8)目标跟踪函数CamShift()使用
人工智能·opencv·目标跟踪
热门推荐
01【HarmonyOS】HUAWEI DevEco Studio 下载地址汇总02(欧拉)openEuler系统添加网卡文件配置流程、(欧拉)openEuler系统手动配置ipv6地址流程、(欧拉)openEuler系统网络管理说明03组基轨迹建模 GBTM的介绍与实现（Stata 或 R）04【AIGC】重塑未来的科技巨轮05全面解析：构建基于深度学习的安全帽检测系统（UI界面+YOLO代码+数据集）06【经验分享】Ubuntu22.04安装微信(linux官方版)07基于YOLOv10深度学习的CT扫描图像肾结石智能检测系统【python源码+Pyqt5界面+数据集+训练代码】深度学习实战、目标检测08Ubuntu 20.04使用Livox mid 360 测试 FAST_LIO09RAG 实践- Ollama+RagFlow 部署本地知识库10【TC3xx芯片】TC3xx芯片电源管理系统PMS详解