关于QT cmake项目添加了.ui文件build未自动生成ui_xxx.h，错误提示找不到这个头文件问题处理

文章目录

- - 问题
  - 分析
  - 举例

问题

当我们想使用cmakelist来编译运行一个QT项目时，当项目中存在Ui文件时，我们可能会遇到ui_XXX.h头文件找不到的问题。这里我们来分析并解决一下问题。

分析

不管是在cmake下或者qmake下的ui_XXX.h都是根据XXX.ui文件自动生成的。
在cmake下，一般来说是使用set(CMAKE_AUTOUIC ON)
这个设置启用了 CMake 的自动处理机制，用于处理 Qt 的 .ui 文件。当设置为 ON 时，CMake 会自动调用 Qt 的 uic 工具，将 .ui 文件编译成相应的头文件（.h 文件）。这些头文件随后可以被包含在项目中，以便在代码中使用由 Qt Designer 设计的界面。
例如，如果你有一个名为 mainwindow.ui 的界面文件，启用 CMAKE_AUTOUIC 后，CMake 会自动生成一个 ui_mainwindow.h 文件，你可以直接在你的代码中包含这个头文件。
还有一个qt5_wrap_ui，作用相似,将它们转换成 C++ 头文件。CMAKE_AUTOUIC 是一个高级选项，它告诉 CMake 自动为所有目标（如可执行文件或库）中的 .ui 文件生成相应的头文件。这意味着你不需要显式地为每个 .ui 文件调用qt5_wrap_ui宏。这在项目中有大量 .ui 文件时非常方便，因为它可以减少重复的配置代码。然而，有时候你可能需要更细粒度的控制，或者 CMAKE_AUTOUIC 无法正确处理某些 .ui 文件。在这种情况下，你可以禁用 CMAKE_AUTOUIC 并显式地使用 qt5_wrap_ui 宏。
当 CMAKE_AUTOUIC 出现问题(版本不兼容)时，通过手动使用 qt5_wrap_ui 可以帮助你更好地解决问题所在
使用 qt5_wrap_ui 宏时还有一个重要的设置set(CMAKE_INCLUDE_CURRENT_DIR ON)
这个设置告诉 CMake 在编译过程中自动将当前源文件所在的目录（也就是源代码文件所在的目录）添加到头文件的搜索路径中。这对于确保编译器可以找到所有相关的头文件非常重要，特别是那些在源文件中直接包含的头文件。例如，如果你的源代码文件 main.cpp 包含了一个位于同一目录下的头文件 mainwindow.h，那么 CMAKE_INCLUDE_CURRENT_DIR ON 会确保编译器在寻找 mainwindow.h 时，会查看 main.cpp 所在的目录，这对我们找到ui_XXX.h头文件很关键。

举例

bash 复制代码

cmake_minimum_required(VERSION 3.0.0)

project(HMI)

set(CMAKE_CXX_STANDARD 11)

set(CMAKE_CXX_STANDARD_REQUIRED ON)

set(CMAKE_AUTOMOC ON)

set(CMAKE_AUTORCC ON)
#不能同时与其使用
# set(CMAKE_AUTOUIC ON)
#找头文件
set(CMAKE_INCLUDE_CURRENT_DIR ON)

file(GLOB header_s 
${CMAKE_CURRENT_LIST_DIR}/*.h
${CMAKE_CURRENT_LIST_DIR}/wizard/page/*.h
)

file(GLOB soucer_s 
${CMAKE_CURRENT_LIST_DIR}/*.cpp
${CMAKE_CURRENT_LIST_DIR}/wizard/page/*.cpp
)

file(GLOB ui_s 
${CMAKE_CURRENT_LIST_DIR}/wizard/ui/*.ui
)
#转换为.h文件
find_package(Qt5 REQUIRED Widgets Gui Core)

qt5_wrap_ui(QT_FORMS_HPP ${ui_s})

add_executable(HMI 
    ${header_s} 
    ${soucer_s}
    ${QT_FORMS_HPP}
)

target_include_directories(HMI 
    PRIVATE
    ${CMAKE_CURRENT_LIST_DIR}
    ${CMAKE_CURRENT_LIST_DIR}/wizard/page
)

target_link_libraries(
    HMI 
    PUBLIC
    Qt5::Widgets 
    Qt5::Gui 
    Qt5::Core 
)

当我们add_executable中不加入 ${QT_FORMS_HPP}代码也是可以编译过的，不过你修改后的Ui文件是不会生效的