AutoHotKey自动热键(二)中文版帮助手册下载和自定义一般键盘快捷键

所有的操作其实在开发者手册中已经交待完了,所以我们要使用中文的手册来进行使用
autohotkey1.1.15中文手册下载
好了,为什么有了中文手册,这里还要进行一些具体的介绍呢,就是为了让大家少踩坑,能够快速形成生产力
这里先讲一下自定义快捷键WIN键和ALT键和CTRL键和SHIFT键的组合
WIN+d组合快捷键 win键可以用#号代替,后面的双冒号是固定用法,结尾一般是要写上return, 而msgbox是一个弹窗, 后面可以直接空格,也可以加上逗号

ahk 复制代码

#d::
	msgbox 123
return

常用符号

#=WIN键
!=ALT键
^=CTRL键
+=SHIFT键

举个例子
CTRL+P就是^P::
SHIFT+CTRL+K就是+^k::
WIN+SHIFT+O就是#+o::
WIN+ALT+SHIFT+U就是#!+u::
变化成代码如下

ahk 复制代码

#d::
	msgbox 按下了WIN+D
return

^P::
	msgbox 按下了CTRL+P
return

+^k::
	msgbox 按下了SHIFT+CTRL+K
return

#+o::
	msgbox 按下了WIN+SHIFT+O
return

#!+u::
	msgbox 按下了WIN+ALT+SHIFT+U
return

与F1到F12的组合

CTRL+F1就是^F1::

ahk 复制代码

^F1::
   msgbox 按下了 CTRL+F1
return

修饰符{传递}(不阻拦原有功能)

~在前面加上这个符号在执行完本脚本之后,按键的消息会继续传给下一个,也就是不会阻挡原来的功能,打个比方WINDOWS系统中有个快捷键功能就是CTRL+SHIFT+ESC唤成任务管理器,如果我们按上面的操作直接使用^+ESC::,那么执行过后会发现任务管理器这个快捷功能被屏蔽了,若此时在前面加上~组合成~^+ESC::就会发现在原来的功能又出现了

ahk 复制代码

~^+ESC::
    msgbox 弹窗的同时并不妨碍原来WINDOWS系统中唤出任务管理器
return

所以上面这个~功能非常重要,因为这个脚本默认就是覆盖掉原有的功能!!!如果不想原有功能被覆盖一定要加上~符号

修饰符{左或右键}

ahk 复制代码

<^o::
    msgbox 左侧的CTRL+O
return

>^o::
    msgbox 右侧的CTRL+O
return

在CTRL键前面加上<或者>可以单独表示按下的是左键盘左侧的CTRL键或者是右侧的键,当然,键盘上分左右的大概只有CTRL和SHIFT和WIN以及ALT了

无视干扰修饰符

在设定了快捷键的时候,有时我们在复杂的按键环境中,比如同时按下了一些无关的按键,那么这个功能就无法执行了,比如

ahk 复制代码

^F8::
    msgbox 按下了CTRL+F8
return

比如上面这种,我们先按下ALT不动,进行干扰,会发现CTRL+F8无法运行,那么这种情况可以加上无视干扰修饰符*

ahk 复制代码

*^F8::
    msgbox CTRL+F8
return

那么这一次按下了ALT进行干扰也同样运行了CTRL+F8

修饰符{弹起}

脚本默认是在按下的时候执行,所以这个UP修饰符就是用来在按键在弹起时执行的

ahk 复制代码

#F1::
    msgbox WIN+F1被按下
Return

#F1 Up::
    msgbox WIN+F1被弹起
Return

上面的按键会先执行按下,后执行弹起

多个按键执行相同功能

ahk 复制代码

#F1::
#F2::
#F3::
#F4::
    msgbox F功能键被按下
Return

这里就是无论按下WIN键+F1 +或者234都是执行相同的功能

自定义功能键

因为键盘上只有四个功能键CTRL+SHIFT+ALT+WIN,那么我们在使用的时候可以添加自定义的功能键,所谓功能键就是按下的时候什么事都不发生,但是在同时按下其它键的时候可以组合出其它功能,这里我们将F11键当成一个功能键去组合其它的按键

ahk 复制代码

F11 & L::
    msgbox F11+L被按下
Return

这里要注意的就是在&符号前面的这个按键会被默认当成功能键,会覆盖掉这个按键之前的功能