判断用户选择的Excel单元格区域是否跨页？

VBA应用程序开发过程中，经常需要处理用户选中的单元格区域，有的应用场景中，需要限制用户选中区域位于同一页中（以打印预览显示的分页划分），但是VBA对象模型中并没有提供相应的接口，用于快速查询单元格位于哪个打印页面中，那么只能自己动手丰衣足食了。

示例代码如下。

复制代码

Function IsOnMultiPg(ByRef rRng As Range)
    Dim rData As Range, HPB As HPageBreak
    Dim beforeC As Range, afterC As Range
    IsOnMultiPg = False
    If rRng.Cells.Count = 1 Then Exit Function
    Set rData = rRng.EntireRow
    For Each HPB In ActiveSheet.HPageBreaks
        Set afterC = HPB.Location
        Set beforeC = afterC.Offset(-1, 0)
        If Not ((Intersect(afterC, rData) Is Nothing) Or (Intersect(beforeC, rData) Is Nothing)) Then
            IsOnMultiPg = True
            Exit For
        End If
    Next
End Function

【代码解析】

第4行代码设置函数默认返回值为False，即没有跨页。

第5行代码判断参数rRng包含的单元格个数，如果是单个单元格，那么退出函数，函数返回值为False。

第6行代码获取指定单元格区域所在的行区域。

注意：为了简化示例代码，本过程仅仅检测单元格区域是否跨越行分页符，使用类似的方法，可以实现检测单元格区域是否跨越列分页符。

第7~14行代码循环遍历行分页符。

第8行代码获取行分页符之下的单元格，例如我的电脑打开示例文件，其第一个分页符位于54行和55行之间（各位读者系统默认打印机的设置将影响分页符的位置，可能与我的并不相同），那么HPB.Location返回值为A55。

第9行代码获取行分页符之上的单元格。

第10行代码判断afterC和beforeC是否和rData单元格区域都有交集。

如果满足上述条件，第11行代码设置返回值为True。

第12行代码退出循环过程。

测试代码如下。

复制代码

Sub Demo()
    Dim r As Range
    For Each r In Range("A50:D54,A50:D66").Areas
    If IsOnMultiPg(r) Then
        Debug.Print r.Address(0, 0) & ": 跨页"
    Else
        Debug.Print r.Address(0, 0) & ": 没有跨页"
    End If
    Next
End Sub

【立即窗口】中输出结果如下：

复制代码

A50:D54: 没有跨页
A50:D66: 跨页