ABAP SQL更新DB小技巧 WITH INDICATORS

在使用HTTP服务时我们更新数据时经常会使用到PUT或者PATCH,PUT的更新是完全以传入的字段信息为准,没有记录时进行创建,存在记录时完全依据传入的数据进行覆盖更新,而PATCH则是可以仅更新指定字段,而不影响其他字段,那在ABAP SQL中其实也有同样的功能,只是大多数时候都是为了方便直接使用了MODIFY语法进行更新(等同于PUT),这就要求如果是要更新记录时,你需要先获取目标数据的完整字段值信息,将你想更改的字段的值修改后,再次更新,那在ABAP Release 758之后,是可以使用WITH INDICATORS来达到PATCH更新的效果的,下面用一个简单的例子来说明下这个小技巧。


创建一张测试表:

TYPES定义更新结构:

复制代码
TYPES:
  ty_dn_ind TYPE ztest_upd_ind WITH INDICATORS ind,
  tt_dn_ind TYPE SORTED TABLE OF ty_dn_ind WITH UNIQUE KEY id.

此处使用WITH INDICATORS关键字定义了一个更新结构,为了方便起见,直接debug看一下定义出来的结构就一眼明白这样定义的效果:

ind 用来指定定义的结构名称,而这个结构的字段和定义的字段完全一致,只是默认类型是X类型,该结构的用处是在更新数据库表格时,起到一个控制的作用,只有当ind 结构中对应的字段设置为01时,才会更新此字段,否则不进行任何更新,这个作用类似于BAPI中的X结构,熟悉RAP开发的顾问应该也已经联想到了,等同于EML语法更新BO时的%control结构。

实际使用例子:

复制代码
*&---------------------------------------------------------------------*
REPORT ztest_update_db_with_ind.

TYPES:
  ty_db_ind TYPE ztest_upd_ind WITH INDICATORS ind,
  tt_db_ind TYPE SORTED TABLE OF ty_db_ind WITH UNIQUE KEY id.

DATA:
  lt_ins TYPE tt_db_ind,
  ls_ind TYPE ty_db_ind,
  lt_upd TYPE tt_db_ind,
  is_ind TYPE ty_db_ind.

DELETE FROM ztest_upd_ind.

lt_ins = VALUE #( ( id = '1' field1 = 'test1' field2 = 'test2' field3 = 'test3' ) ).

INSERT ztest_upd_ind FROM TABLE @lt_ins.

COMMIT WORK AND WAIT.
BREAK-POINT.

lt_upd = VALUE #( ( id = '1' field1 = 'test1->change' ind-field1 = '01' ) ).

UPDATE ztest_upd_ind FROM TABLE @lt_upd INDICATORS SET STRUCTURE ind.

COMMIT WORK AND WAIT.
BREAK-POINT.

以上代码第一步,先清空测试表,然后插入一条测试数据:

然后构建更新内表,在设置主键之后,我们仅更新FIELD1字段,并且为FIELD1的控制字段设置为01,可以看到在更新之后,底表中仅FIELD1字段进行了变更,其他字段不受影响。

当然这个控制结构的类型可以使用关键字TYPE 自行执行,比如WITH INDICATORS ind TYPE abap_boolean,这样一来控制结构的类型就不再是00 或者01 来控制,而是abap_trueabap_false来控制,但是建议还是使用默认的类型,这样一来在RAP有些场景需要动态处理时,可以快速的进行mapping。

以上。

相关推荐
好望角雾眠1 天前
第三阶段数据库-7:sql中函数,运算符,常用关键字
数据库·笔记·sql·学习·sqlserver·c#
做一个AC梦2 天前
MiniOB环境部署开发(使用Docker)
数据库·sql·miniob·ob·海扬数据库
l1t2 天前
分析xml标签属性和压缩级别对xlsx文件读取解析的影响
xml·开发语言·python·sql·duckdb
DONG9132 天前
Redis内存架构解析与性能优化实战
数据库·redis·sql·database
武昌库里写JAVA2 天前
使用 Java 开发 Android 应用:Kotlin 与 Java 的混合编程
java·vue.js·spring boot·sql·学习
水涵幽树2 天前
MySQL 时间筛选避坑指南:为什么格式化字符串比较会出错?
数据库·后端·sql·mysql·database
funfan05173 天前
在IDEA中DEBUG调试时查看MyBatis-Plus动态生成的SQL语句
sql·intellij-idea·mybatis
AI 嗯啦3 天前
SQL详细语法教程(七)核心优化
数据库·人工智能·sql
不羁。。3 天前
【撸靶笔记】第八关:GET - Blind - Boolian Based - Single Quotes
数据库·sql·mybatis
麻辣清汤3 天前
结合BI多维度异常分析(日期-> 商家/渠道->日期(商家/渠道))
数据库·python·sql·finebi