Android grade9.0 之后 自定义apk 名称

import java.text.SimpleDateFormat
import java.util.* 
import com.android.build.api.variant.FilterConfiguration
import com.android.build.api.variant.impl.VariantOutputImpl 


plugins {
    alias(libs.plugins.android.application)
    alias(libs.plugins.kotlin.compose)
}



android {
    namespace = "com.lam.project"
    compileSdk {
        version = release(36) {
            minorApiLevel = 1
        }
    }

    defaultConfig {
        applicationId = "com.lam.project"
        minSdk = 24
        targetSdk = 36
        versionCode = 1
        versionName = "1.0"

        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"

        splits {
            abi{
                val isReleaseBuild = gradle.startParameter.taskNames.any { taskName ->
                    // 启用不同构建变体的发布构建拆分
                    // (assemblePaidRelease, assembleFreeRelease 等)。
                    taskName.matches(Regex(":app:assemble.*Release"))
                }
                // 只有Release包启用拆包
                isEnable = isReleaseBuild
                reset() // 重置所有配置
                include("armeabi-v7a", "arm64-v8a") // 生成arm64-v8a 和 armeabi-v7a 架构分别的 apk
                isUniversalApk = true // 生成包含ndk设置的所有ABI的附加APK

            }
        }
    }

    buildTypes {
        release {
            isMinifyEnabled = false
            proguardFiles(
                getDefaultProguardFile("proguard-android-optimize.txt"),
                "proguard-rules.pro"
            )
        }
    }
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_11
        targetCompatibility = JavaVersion.VERSION_11
    }
    buildFeatures {
        compose = true
    }


    //noinspection WrongGradleMethod
    androidComponents {
        onVariants(selector().all()) { variant ->

            variant.outputs.forEach { output ->
                val outputImpl = (output as VariantOutputImpl)

                // 获取 ABI
                val abi = output.filters
                    .firstOrNull { it.filterType == FilterConfiguration.FilterType.ABI }
                    ?.identifier

                val abiName = when (abi) {
                    "arm64-v8a" -> "64位"
                    "armeabi-v7a" -> "32位"
                    null -> "64+32" // universal APK
                    else -> abi
                }

                val dateFormat = SimpleDateFormat("yyyyMMdd-HH:mm:ss")
                val currentDate = dateFormat.format(Date())

                val versionName = libs.versions.appVersionName.get()
                val versionCode = libs.versions.appVersionCode.get()

                val buildType = variant.name

                val apkName =
                    "${buildType}-${versionName}(${versionCode})(${abiName})-$currentDate.apk"
                outputImpl.outputFileName.set(apkName)
            }
        }
    }

}



dependencies {
    implementation(libs.androidx.core.ktx)
    implementation(libs.androidx.lifecycle.runtime.ktx)
    implementation(libs.androidx.activity.compose)
    implementation(platform(libs.androidx.compose.bom))
    implementation(libs.androidx.compose.ui)
    implementation(libs.androidx.compose.ui.graphics)
    implementation(libs.androidx.compose.ui.tooling.preview)
    implementation(libs.androidx.compose.material3)
    testImplementation(libs.junit)
    androidTestImplementation(libs.androidx.junit)
    androidTestImplementation(libs.androidx.espresso.core)
    androidTestImplementation(platform(libs.androidx.compose.bom))
    androidTestImplementation(libs.androidx.compose.ui.test.junit4)
    debugImplementation(libs.androidx.compose.ui.tooling)
    debugImplementation(libs.androidx.compose.ui.test.manifest)
}