Solidity 小白教程：23. Delegatecall

delegatecall

delegatecall 与call 类似，是solidity 中地址类型的低级成员函数。delegate 中是委托/代表的意思，那么delegatecall 委托了什么？

当用户A 通过合约B 来call 合约C 的时候，执行的是合约C 的函数，语境 (Context ，可以理解为包含变量和状态的环境)也是合约C 的：msg.sender 是B 的地址，并且如果函数改变一些状态变量，产生的效果会作用于合约C 的变量上。

而当用户A 通过合约B 来delegatecall 合约C 的时候，执行的是合约C 的函数，但是语境仍是合约B 的：msg.sender 是A 的地址，并且如果函数改变一些状态变量，产生的效果会作用于合约B 的变量上。

大家可以这样理解：一个富商把它的资产（状态变量 ）都交给一个VC 代理（目标合约 的函数）来打理。执行的是VC 的函数，但是改变的是富商的状态。
delegatecall 语法和call类似，也是：

solidity 复制代码

目标合约地址.delegatecall(二进制编码);

其中二进制编码 利用结构化编码函数abi.encodeWithSignature获得：

solidity 复制代码

abi.encodeWithSignature("函数签名", 逗号分隔的具体参数)

函数签名 为**"函数名（逗号分隔的参数类型)"。例如 abi.encodeWithSignature("f(uint256,address)", _x, _addr)。
和 call不一样，delegatecall在调用合约时可以指定交易发送的 gas**，但不能指定发送的ETH 数额
注意**：****delegatecall****有安全隐患，使用时要保证当前合约和目标合约的状态变量存储结构相同，并且目标合约安全，不然会造成资产损失。**

什么情况下会用到delegatecall?

目前delegatecall主要有两个应用场景：

代理合约（Proxy Contract ）：将智能合约的存储合约和逻辑合约分开：代理合约（Proxy Contract ）存储所有相关的变量，并且保存逻辑合约的地址；所有函数存在逻辑合约（Logic Contract ）里，通过delegatecall执行。当升级时，只需要将代理合约指向新的逻辑合约即可。
EIP-2535 Diamonds（钻石）：钻石是一个支持构建可在生产中扩展的模块化智能合约系统的标准。钻石是具有多个实施合同的代理合同。更多信息请查看：钻石标准简介。

delegatecall例子

调用结构：你（A ）通过合约B 调用目标合约C。

被调用的合约 C

我们先写一个简单的目标合约C ：有两个public 变量：num 和sender ，分别是uint256 和address 类型；有一个函数，可以将num 设定为传入的**_num**，并且将sender 设为msg.sender。

solidity 复制代码

// 被调用的合约C
contract C {
    uint public num;
    address public sender;

    function setVars(uint _num) public payable {
        num = _num;
        sender = msg.sender;
    }
}

发起调用的合约 B

首先，合约B 必须和目标合约C 的变量存储布局必须相同，两个变量，并且顺序为num 和sender

solidity 复制代码

contract B {
    uint public num;
    address public sender;

接下来，我们分别用call 和delegatecall 来调用合约C 的setVars 函数，更好的理解它们的区别。
callSetVars 函数通过call 来调用setVars 。它有两个参数**_addr和 _num**，分别对应合约C 的地址和setVars的参数。

solidity 复制代码

// 通过call来调用C的setVars()函数，将改变合约C里的状态变量
    function callSetVars(address _addr, uint _num) external payable{
        // call setVars()
        (bool success, bytes memory data) = _addr.call(
            abi.encodeWithSignature("setVars(uint256)", _num)
        );
    }

而delegatecallSetVars 函数通过delegatecall 来调用setVars 。与上面的callSetVars 函数相同，有两个参数**_addr和 _num**，分别对应合约C 的地址和setVars的参数。

solidity 复制代码

// 通过delegatecall来调用C的setVars()函数，将改变合约B里的状态变量
    function delegatecallSetVars(address _addr, uint _num) external payable{
        // delegatecall setVars()
        (bool success, bytes memory data) = _addr.delegatecall(
            abi.encodeWithSignature("setVars(uint256)", _num)
        );
    }
}

在 remix 上验证

首先，我们把合约B 和C都部署好

部署之后，查看C 合约状态变量的初始值，B合约的状态变量也是一样。

此时，调用合约B 中的callSetVars ，传入参数为合约C 地址和10

运行后，合约C 中的状态变量将被修改：num 被改为10 ，sender 变为合约B的地址

接下来，我们调用合约B 中的delegatecallSetVars ，传入参数为合约C 地址和100

由于是delegatecall ，语境为合约B 。在运行后，合约B 中的状态变量将被修改：num 被改为100 ，sender 变为你的钱包地址。合约C中的状态变量不会被修改。

总结

这一讲我们介绍了solidity 中的另一个低级函数delegatecall 。与call 类似，它可以用来调用其他合约；不同点在于运行的语境，B call C ，语境为C ；而B delegatecall C ，语境为B 。目前delegatecall 最大的应用是代理合约和EIP-2535 Diamonds（钻石）。