目录
前言：
蛐蛐：这个人又在拟一些夸张的标题试图吸引读者。
最近公司全面开始使用钉钉，用户想要将SAP的消息推送到钉钉，可以推送消息给公司的具体某个人，也可以推送消息到某个群聊。
做出来的效果如下：
今天就来分享一下，我具体是怎么实现的吧，老样子，文末有代码分享~
一、钉钉配置
因为钉钉有上线一个新功能，叫做AI表格，功能也是蛮强大的，这次我就使用了AI表格中的自动化流程中的webhook接口。（PS：这个和钉钉的机器人连接方式有区别哦，请注意我这里是AI表格-自动化-webhook！webhook连接要比机器人API连接要简单一点）。
1、AI表格创建
问题来了，要是钉钉没有AI表格怎么办，emmm有可能是版本没升级^_^
首先我们创建一个自己使用的AI表格，我这里使用的是空白模板，我们在表格里面可以设置一些字段，就和EXCEL差不多的，这个表格等会儿可以当作后台表来存放我们从SAP传过来的一些数据，类似于SAP的后台日志表一样的功能。
我是像下面这样设置的，比较简单：
2、自动化流程设置
设置好日志表的字段后，我们的视线上移，可以看到这里有个"自动化"，我们点击自动化，进入自动化流程配置：
进入后，可以进行一些自动化配置，功能非常完善，我的自动化流程配置如下:
配置完成之后，就相当于在钉钉系统增加了一个接口，SAP可以调用这个接口，给钉钉系统发送数据，钉钉成功接收数据之后，可以利用这些数据自行做后面一系列的操作，类似于给某人发送消息、给某个群聊发送消息、给某人增加待办等等操作，这是钉钉里面的操作了，这里就不做细讲，钉钉也有专门出过一些教程，大家有兴趣可以直接进钉钉里面查看。
3、webhook接口参数：
接着我们开始来讲webhook，这是我今天的重点哈哈，webhook其实就相当于一个API、一个接口，那接口的话，传输数据肯定是需要参数字段的撒，我的参数设置如下：
附上钉钉的官方操作文档连接：https://wolai.dingtalk.com/oDZLkD5ifBR9eU9DEwT7ie
二、SAP开发
我们就像连接其他别的API/restful接口一样，连接钉钉的webhook接口就可以了，注意，我这里是将这个接口封装起来了，我只需要在程序中调用封装的这个接口就可以了。
调用效果如下：
1、接口开发
让我们我们直击接口内部，走进代码现场。
对于接口参考，我最在乎的是参数设置，我这样设置的：是我将文本字段设置成了一个结构
下面红框里面的代码就是实现webhook的参数结构的代码：
整体代码如下：
FUNCTION ZTEST_API.
*"----------------------------------------------------------------------
*"*"本地接口：
*" IMPORTING
*" REFERENCE(I_BUDAT) TYPE BUDAT
*" REFERENCE(I_TYPE) TYPE BAPI_MTYPE
*" EXPORTING
*" VALUE(E_MSEG) TYPE BAPI_MSG
*" VALUE(E_TYPE) TYPE BAPI_MTYPE
*" TABLES
*" T_TAB STRUCTURE ZTXX_WEBHOOK
*"-------------------------------------------------------------------
DATA: LV_ECS_JSON_REQ TYPE STRING,
LV_ECS_JSON_RES TYPE STRING,
LV_URL TYPE STRING,
LV_RESPONSE TYPE STRING.
DATA: LO_HTTP_CLIENT TYPE REF TO IF_HTTP_CLIENT.
DATA: LO_EXCEPTION TYPE REF TO CX_ROOT.
DATA: LV_ERROR_TEXT TYPE STRING.
TYPES: TY_DETAILS TYPE STANDARD TABLE OF ZTXX_WEBHOOK WITH DEFAULT KEY.
TYPES: BEGIN OF TY_REQUEST,
BUDAT TYPE BUDAT,
TYPE1 TYPE BAPI_MTYPE,
TAB TYPE TY_DETAILS,
END OF TY_REQUEST.
TYPES: BEGIN OF TY_RESPONSE,
DATA TYPE ABAP_BOOL,
SUCCESS TYPE ABAP_BOOL,
END OF TY_RESPONSE.
DATA: LS_REQUEST TYPE TY_REQUEST,
LS_RESPONSE TYPE TY_RESPONSE.
* 1. 准备请求数据
LS_REQUEST = VALUE #(
BUDAT = I_BUDAT
TYPE1 = I_TYPE
).
APPEND LINES OF T_TAB[] TO LS_REQUEST-TAB.
* 2. 序列化请求数据
TRY.
LV_ECS_JSON_REQ = /UI2/CL_JSON=>SERIALIZE(
DATA = LS_REQUEST
PRETTY_NAME = /UI2/CL_JSON=>PRETTY_MODE-LOW_CASE
).
CATCH CX_ROOT INTO LO_EXCEPTION.
E_MSEG = 'JSON序列化失败: ' && LO_EXCEPTION->GET_TEXT( ).
E_TYPE = 'E'.
RETURN.
ENDTRY.
* 3. 设置URL（固定地址，可以配置成后台表去读取）
LV_URL = 'webhook地址'."要自己替换哈
* 4. 创建HTTP客户端
TRY.
CALL METHOD CL_HTTP_CLIENT=>CREATE_BY_URL
EXPORTING
URL = LV_URL
IMPORTING
CLIENT = LO_HTTP_CLIENT
EXCEPTIONS
ARGUMENT_NOT_FOUND = 1
PLUGIN_NOT_ACTIVE = 2
INTERNAL_ERROR = 3
OTHERS = 4.
IF SY-SUBRC <> 0.
E_MSEG = '创建HTTP客户端失败'.
E_TYPE = 'E'.
RETURN.
ENDIF.
CATCH CX_ROOT INTO LO_EXCEPTION.
E_MSEG = '创建HTTP客户端异常: ' && LO_EXCEPTION->GET_TEXT( ).
E_TYPE = 'E'.
RETURN.
ENDTRY.
** 5. 配置请求头
LO_HTTP_CLIENT->REQUEST->SET_METHOD( 'POST' ).
LO_HTTP_CLIENT->REQUEST->SET_CONTENT_TYPE( 'application/json' ).
LO_HTTP_CLIENT->REQUEST->SET_HEADER_FIELD(
NAME = 'OperationCode'
VALUE = 'xxxx.webhook' )."要自己替换哈
LO_HTTP_CLIENT->REQUEST->SET_HEADER_FIELD(
NAME = 'ClientId'
VALUE = 'XXX' )."要自己替换哈
** 设置请求数据
LO_HTTP_CLIENT->REQUEST->SET_CDATA( LV_ECS_JSON_REQ ).
* 6. 发送请求
TRY.
LO_HTTP_CLIENT->SEND(
EXCEPTIONS
HTTP_COMMUNICATION_FAILURE = 1
HTTP_INVALID_STATE = 2
OTHERS = 3
).
IF SY-SUBRC <> 0.
LV_ERROR_TEXT = '发送请求失败'.
IF SY-SUBRC = 1.
LV_ERROR_TEXT = 'HTTP通信失败'.
ELSEIF SY-SUBRC = 2.
LV_ERROR_TEXT = 'HTTP状态无效'.
ENDIF.
E_MSEG = LV_ERROR_TEXT.
E_TYPE = 'E'.
LO_HTTP_CLIENT->CLOSE( ).
RETURN.
ENDIF.
CATCH CX_ROOT INTO LO_EXCEPTION.
E_MSEG = '发送请求异常: ' && LO_EXCEPTION->GET_TEXT( ).
E_TYPE = 'E'.
LO_HTTP_CLIENT->CLOSE( ).
RETURN.
ENDTRY.
* 7. 接收响应
TRY.
LO_HTTP_CLIENT->RECEIVE(
EXCEPTIONS
HTTP_COMMUNICATION_FAILURE = 1
HTTP_INVALID_STATE = 2
OTHERS = 3
).
IF SY-SUBRC <> 0.
LV_ERROR_TEXT = '接收响应失败'.
IF SY-SUBRC = 1.
LV_ERROR_TEXT = 'HTTP通信失败'.
ELSEIF SY-SUBRC = 2.
LV_ERROR_TEXT = 'HTTP状态无效'.
ENDIF.
E_MSEG = LV_ERROR_TEXT.
E_TYPE = 'E'.
LO_HTTP_CLIENT->CLOSE( ).
RETURN.
ENDIF.
CATCH CX_ROOT INTO LO_EXCEPTION.
E_MSEG = '接收响应异常: ' && LO_EXCEPTION->GET_TEXT( ).
E_TYPE = 'E'.
LO_HTTP_CLIENT->CLOSE( ).
RETURN.
ENDTRY.
* 8. 获取响应数据
LV_RESPONSE = LO_HTTP_CLIENT->RESPONSE->GET_CDATA( ).
* 9. 关闭连接
LO_HTTP_CLIENT->CLOSE( ).
* 10. 解析响应数据
TRY.
/UI2/CL_JSON=>DESERIALIZE(
EXPORTING
JSON = LV_RESPONSE
PRETTY_NAME = /UI2/CL_JSON=>PRETTY_MODE-LOW_CASE
CHANGING
DATA = LS_RESPONSE
).
CATCH CX_ROOT INTO LO_EXCEPTION.
E_MSEG = 'JSON反序列化失败: ' && LO_EXCEPTION->GET_TEXT( ).
E_TYPE = 'E'.
RETURN.
ENDTRY.
* 11. 处理响应结果
IF LS_RESPONSE-SUCCESS = ABAP_TRUE.
E_TYPE = 'S'.
E_MSEG = '接口调用成功'.
ELSE.
E_TYPE = 'E'.
E_MSEG = '接口调用失败'.
ENDIF.
ENDFUNCTION.注释都在代码里面，复制就可以使用，但是要注意url等参数更改为自己的钉钉webbhook地址
2、接口测试
当我们把接口开发完之后，就可以测试了，和我们平时测试接口的方式一样，就填写数据，然后访问webhook，看是否请求成功就可以了。不过测试的时候要注意哟，我们连接的是钉钉的正式环境哟，不要发很多奇奇怪怪的消息哈。
按照上述的步骤，应该是可以成功的，不过还有一些经验要分享。如果你到这一步骤已经成功了，那就恭喜你啦，真棒！如果到这一步骤你还没有成功，别急，我最开始也失败了，我们来接着看，我有一些经验要继续分享~
三、一些经验
1、上面分享的代码是已经成功联通钉钉的代码，从上面的代码可以看出，我们没有去调用钉钉的接口获取token，所以当你的SAP连接钉钉webhook接口联不通的时候，不用怀疑token的问题，因为连接钉钉webhook是不需要获取token的。
2、请求头的设置，正常只需要设置post方法和application/json格式就可以了，也不用怀疑请求头，不过如果你写了的话，一定要保证是正确的哦。
3、我在测试时的致命bug是，同样的参数、格式、请求头，我使用POSTMAN调用webhook就是成功的，但是我使用SAP去调用webhook就失败了。
四、BUG解决
由于这一部分内容太多，单独拎出来做成一小节单独讲解。
不知道你是不是很困惑，反正我是很困惑了。因为我们公司没有basis顾问，所以我请教了我们运维网络的同事：
我和文老师从服务器、网络、网络权限、代理等各个地方都排查了一遍，最后在SAP系统使用SMICM监测后，发现是安全证书的问题！（可以把报错复制下来问AI，红色的就是数据本身带的颜色，很明显，但是数据量太大了，有可能一滑就过了就不容易发现，这个人刚刚好像说了一个病句，没关系，能够找到问题就是了）
我自己从网页上下载的是好像什么G2证书，这里面有提示是说要提供R3证书，所以校验还是不通过的。
下面是文老师和AI的分析：
因为我确实找不到R3根证书，所以我去我们钉钉实施顾问那里反馈了，她是三方外包的团队，也没有办法解决这种问题，但是她非常热心地帮我向钉钉官方提交了一个问题工单，邀请了钉钉官方的技术顾问帮忙解决。
但是！官方技术顾问拒绝了提供R3根证书给我，并回答我这个证书涉及安全问题，不能提供。所以也没有办法再要求人家什么了（这一part没有截图，因为问题无解，然后工单结束了，然后群聊解散了哈哈）
就在我一度快要放弃的时候！嗯哼~灵机一动，我突然想到了我们的中间系统。
我必须画个图来体现一下，上图：
左边没有使用中间系统，失败；右边使用了中间系统，成功
ESB 即企业服务总线（Enterprise Service Bus），是一种企业级的软件架构模式和中间件技术。 从架构层面看，它是一个在企业信息系统环境中用于集成各种不同应用程序、服务和系统的通信中枢。 这个中枢提供了一个统一的通信平台，使企业内部（如不同部门的业务系统）和外部（如与合作伙伴的系统）的软件组件能够相互交互，就像城市中的公共交通系统，各个地点（软件系统）通过公交网络（ESB）连接起来。（就是类似数据中台、日志系统这种）
总的来说就是，SAP系统和ESB系统之间是可以联通的；而钉钉和ESB系统也是联通的。所以，通过ESB转发一下请求，SAP和钉钉就可以绕开安全证书的检验而连接上了，好啦~大功告成！
看一下钉钉的webhook后台记录吧！
只要数据成功从SAP到了钉钉系统，那么剩余的事情就好办了，利用钉钉AI表格里面自带的自动化功能，数据想怎么使用就怎么使用，存表、发到群聊、单独发给某人、给某人添加待办事项、做数据分析等等都可以，这里面就是钉钉的功能了，我就不过多介绍啦。
那么，事已至此，告辞！