【ARM】Day4 点亮LED灯

1. 思维导图

2. 自己编写代码实现三盏灯点亮

复制代码
.text 
.global _start
_start: 
	/**********LED1,LED2,LED3点灯:PE10,PF10,PE8**************/
RCC_INIT:
	@使能GPIOE组/GPIOF组控制器,通过RXCC_MP_AHB4ENSETR设置第[5:4]位写1,地址:0x50000A28[5:4]=1
	ldr r0,=0x50000A28  	@通过RCC使能GPIO E组 F组
	ldr r1,[r0]
	orr r1,r1,#(0x1<<4) 	@ E组
	orr r1,r1,#(0x1<<5) 	@ F组
	str r1,[r0]


LED1_INTI:
	@设置PE10引脚为输出模式,通过GPIOE_MODER寄存器设置第[21:20]位写01, 地址:0x50006000[21:20]=01
	ldr r0,=0x50006000    	@设置GPIO为输出模式0x50006000[21:20] = 01
	ldr r1,[r0]
	orr r1,r1,#(1<<20)  @置1
	bic r1,r1,#(1<<21) 	@清0
	str r1,[r0]

	@设置PE10引脚为推挽输出类型,通过GPIOE_OTYPER寄存器设置第[10]位写0, 地址:0x50006000[10]=0
	ldr r0,=0x50006004 		@推挽输出 0x50006004[10] = 0
	ldr r1,[r0]
	bic r1,r1,#(1<<10)
	str r1,[r0]
	
	@设置PE10引脚为低速输出,通过GPIOE_OSPEEDE寄存器设置第[21:20]位写00, 地址:0x50006000[21:20]=00
	ldr r0,=0x50006008 		@设置输出速率 0x50006008[21:20] = 00
	ldr r1,[r0]
	bic r1,r1,#(0x3<<20)
	str r1,[r0]
	
	@设置PE10引脚为禁止上下拉电阻,通过GPIOE_PUPDR寄存器设置第[21:20]位写00, 地址:0x50006000[21:20]=00
	ldr r0,=0x5000600c 		@设置输出禁止上拉和下拉 0x5000600c[21:20] = 00
	ldr r1,[r0]
	bic r1,r1,#(0x3<<20)
	str r1,[r0]

LED2_INTI:
	@设置PF10引脚为输出模式,通过GPIOF_MODER寄存器设置第[21:20]位写01, 地址:0x50007000[21:20]=01
	ldr r0,=0x50007000    	@设置GPIO为输出模式0x50007000[21:20] = 01
	ldr r1,[r0]
	orr r1,r1,#(1<<20) 
	bic r1,r1,#(1<<21) 
	str r1,[r0]

	@设置PF10引脚为推挽输出类型,通过GPIOF_OTYPER寄存器设置第[10]位写0, 地址:0x50007000[10]=0
	ldr r0,=0x50007004 		@推挽输出 0x50007004[10] = 0
	ldr r1,[r0]
	bic r1,r1,#(1<<10)
	str r1,[r0]

	@设置PF10引脚为低速输出,通过GPIOF_OSPEEDE寄存器设置第[21:20]位写00, 地址:0x50007000[21:20]=00
	ldr r0,=0x50007008 		@设置输出速率 0x50007008[21:20] = 00
	ldr r1,[r0]
	bic r1,r1,#(0x3<<20)
	str r1,[r0]

	@设置PF10引脚为禁止上下拉电阻,通过GPIOF_PUPDR寄存器设置第[21:20]位写00, 地址:0x50007000[21:20]=00
	ldr r0,=0x5000700c 		@设置输出禁止上拉和下拉 0x5000700c[21:20] = 00
	ldr r1,[r0]
	bic r1,r1,#(0x3<<20)
	str r1,[r0]

LED3_INTI:
	@设置PE8引脚为输出模式,通过GPIOE_MODER寄存器设置第[17:16]位写01, 地址:0x50006000[17:16]=01
	ldr r0,=0x50006000    	@设置GPIO为输出模式0x50006000[17:16] = 01
	ldr r1,[r0]
	orr r1,r1,#(1<<16) 
	bic r1,r1,#(1<<17) 
	str r1,[r0]

	@设置PE8引脚为推挽输出类型,通过GPIOE_OTYPER寄存器设置第[8]位写0, 地址:0x50006000[8]=0
	ldr r0,=0x50006004 		@推挽输出 0x50006004[8] = 0
	ldr r1,[r0]
	bic r1,r1,#(1<<8)
	str r1,[r0]

	@设置PE8引脚为低速输出,通过GPIOE_OSPEEDE寄存器设置第[17:16]位写00, 地址:0x50006000[17:16]=00
	ldr r0,=0x50006008 		@设置输出速率 0x50006008[17:16] = 00
	ldr r1,[r0]
	bic r1,r1,#(0x3<<16)
	str r1,[r0]

	@设置PE8引脚为禁止上下拉电阻,通过GPIOE_PUPDR寄存器设置第[17:16]位写00, 地址:0x50006000[17:16]=00
	ldr r0,=0x5000600c 		@设置输出禁止上拉和下拉 0x5000600c[17:16] = 00
	ldr r1,[r0]
	bic r1,r1,#(0x3<<16)
	str r1,[r0]

loop:
	bl LED1_ON
	bl LED2_ON
	bl LED3_ON
	bl delay_1s
	bl LED1_OFF
	bl LED2_OFF
	bl LED3_OFF
	bl delay_1s
	b loop



LED1_ON:
	ldr r0,=0x50006014 		@设置输出高电平 0x50006014[10] = 1
	ldr r1,[r0]
	orr r1,r1,#(1<<10)
	str r1,[r0]
	mov pc,lr

LED1_OFF:
	ldr r0,=0x50006014 		@设置输出低电平 0x50006014[10] = 0
	ldr r1,[r0]
	bic r1,r1,#(1<<10)
	str r1,[r0]
	mov pc,lr


LED2_ON:
	ldr r0,=0x50007014 		@设置输出高电平 0x50007014[10] = 1
	ldr r1,[r0]
	orr r1,r1,#(1<<10)
	str r1,[r0]
	mov pc,lr

LED2_OFF:
	ldr r0,=0x50007014 		@设置输出低电平 0x50007014[10] = 0
	ldr r1,[r0]
	bic r1,r1,#(1<<10)
	str r1,[r0]
	mov pc,lr

LED3_ON:
	ldr r0,=0x50006014 		@设置输出高电平 0x50006014[8] = 1
	ldr r1,[r0]
	orr r1,r1,#(1<<8)
	str r1,[r0]
	mov pc,lr


LED3_OFF:
	ldr r0,=0x50006014 		@设置输出低电平 0x50006014[8] = 0
	ldr r1,[r0]
	bic r1,r1,#(1<<8)
	str r1,[r0]
	mov pc,lr


@ 大概1s的延时函数
delay_1s:
	mov r3, #0x10000000
	mm:
	cmp r3, #0 			@ r3和0比较
	subne r3, r3, #1 	@ 不相等,r3=r3-1
	bne mm 				@ 不相等,就跳转到mm
	mov pc, lr  		@ 恢复现场

.end

3. 点灯流程

相关推荐
晶振厂家-晶发电子3 天前
晶振在5G时代的角色:高精度时钟的核心支撑
单片机·嵌入式硬件·5g·晶振·电子元器件·晶振知识
F137298015573 天前
WD5030A 芯片,12V降5V,输出电流12A,电路设计
stm32·单片机·嵌入式硬件·汽车·51单片机
小莞尔3 天前
【51单片机】【protues仿真】基于51单片机的篮球计时计分器系统
c语言·stm32·单片机·嵌入式硬件·51单片机
三佛科技-187366133973 天前
分享机械键盘MCU解决方案
单片机·嵌入式硬件·计算机外设
李永奉3 天前
51单片机-使用IIC通信协议实现EEPROM模块教程
单片机·嵌入式硬件·51单片机
小莞尔3 天前
【51单片机】【protues仿真】 基于51单片机八路抢答器系统
c语言·开发语言·单片机·嵌入式硬件·51单片机
bing_feilong3 天前
STM32精准控制水流
单片机·嵌入式硬件
Hello_Embed4 天前
STM32HAL 快速入门(二十):UART 中断改进 —— 环形缓冲区解决数据丢失
笔记·stm32·单片机·学习·嵌入式软件
一起搞IT吧4 天前
嵌入式ARM SOC开发中文专题分享一:ARM SOC外围资源介绍
arm开发·嵌入式硬件
研华嵌入式4 天前
如何在高通跃龙QCS6490 Arm架构上使用Windows 11 IoT企业版?
arm开发·windows·嵌入式硬件