Unity中Shader的XRay透视效果

文章目录

前言
一、模拟菲涅尔效果
- [1、获取 V 向量](#1、获取 V 向量)
- [2、获取 N 向量](#2、获取 N 向量)
- 3、点积输出效果
- 4、模拟出菲涅尔效果(中间暗，周围亮)
[二、实现ＸRay 效果](#二、实现ＸRay 效果)
- 1、使用半透明排序、修改混合模式、加点颜色
- [2、增加分层效果（使用 frac 函数，只取小数部分）](#2、增加分层效果（使用 frac 函数，只取小数部分）)
- 3、增加分层流动效果
- [4、把深度测试改为大于等于通过，以实现 XRay 效果](#4、把深度测试改为大于等于通过，以实现 XRay 效果)
- 最终代码

前言

Unity中Shader的XRay透视效果（该效果一般用于，被建筑物遮挡角色时，给角色显形时使用）

一、模拟菲涅尔效果

就是模拟出像之前光照一样，模型中间亮，周围暗的相反效果
使用模型顶点指向摄像机的单位向量与顶点法向量点积后的结果

fixed3 VdotN = dot(V,N);

1、获取 V 向量

使用摄像机的世界坐标 - 模型顶点的世界坐标

v2f中：

float3 worldPos : TEXCOORD1;

顶点着色器中：

//使用矩阵变换，把模型的顶点坐标转化为世界坐标

o.worldPos = mul(unity_ObjectToWorld,v.vertex);

片元着色器中：

fixed3 V = normalize(_WorldSpaceCameraPos - i.worldPos);

2、获取 N 向量

把模型的顶点法向量转化为世界坐标即可

appdata中:

half3 normal : NORMAL;

v2f中：

//存放世界空间下的法向量

half3 worldNormal : TEXCOORD2;

顶点着色器中：

//把顶点法向量转化为世界坐标

o.worldNormal = UnityObjectToWorldNormal(v.normal);

片元着色器中：

fixed3 N = normalize(i.worldNormal);

3、点积输出效果

fixed VdotN = dot(V,N);

return VdotN;

4、模拟出菲涅尔效果(中间暗，周围亮)

fixed fresnel = 2 * pow(1- VdotN,2);

二、实现ＸRay 效果

1、使用半透明排序、修改混合模式、加点颜色

//使用半透明排序

Tags{"Queue" = "Transparent"}

Blend One One

加点颜色

c.rgb = fresnel * fixed4(1,0,4,0);

return c;

2、增加分层效果（使用 frac 函数，只取小数部分）

fixed v = frac(i.worldPos.x * 20);

c.rgb *= v;

3、增加分层流动效果

//做出流动分层的效果

fixed v = frac(i.worldPos.y * 20 - _Time.w);

c.rgb *= v;

4、把深度测试改为大于等于通过，以实现 XRay 效果

修改前（ZTest Less 小于等于）

修改后（ZTest Greater 大于等于）

最终代码

复制代码

//XRay效果
Shader "Unlit/P1_6_4"
{
    SubShader
    {
        Pass
        {
            //使用半透明排序
            Tags{"Queue" = "Transparent"}
            
            Blend One One
            
            ZTest Greater
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                //传入顶点法向量
                half3 normal : NORMAL;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
                //存放模型顶点的世界坐标
                float3 worldPos : TEXCOORD1;
                //存放世界空间下的法向量
                half3 worldNormal : TEXCOORD2;
            };
            

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                //使用矩阵变换，把模型的顶点坐标转化为世界坐标
                o.worldPos = mul(unity_ObjectToWorld,v.vertex);
                //把顶点法向量转化为世界坐标
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 c = 1;
                //得到从模型顶点 指向 摄像机的 单位向量 
                fixed3 V = normalize(_WorldSpaceCameraPos - i.worldPos);
                //得到模型世界坐标下的法向量
                fixed3 N = normalize(i.worldNormal);
                //计算点积
                fixed VdotN = dot(V,N);
                //模拟菲涅尔效果（中间暗周围亮）
                fixed fresnel = 2 * pow(1 - VdotN,2);

                c.rgb = fresnel * fixed4(1,0,4,0);

                //做出流动分层的效果
                fixed v = frac(i.worldPos.y * 20  - _Time.y);

                c.rgb *= v;
                return c;
            }
            ENDCG
        }
    }
}