Mr. Cappuccino的第69杯咖啡——Oracle之存储过程

Mr. Cappuccino2024-01-17 16:32

Oracle之存储过程

准备数据

sql 复制代码 
create table EMP
(
    NO      NUMBER,
    NAME    VARCHAR2(50),
    SALARY  NUMBER,
    ADDRESS VARCHAR2(200)
);

insert into EMP
select 1, '德玛西亚', 1580, '上海市宝山区'
from dual;
insert into EMP
select 2, '诺克萨斯', 2580, '上海市徐汇区'
from dual;
insert into EMP
select 3, '艾欧尼亚', 3580, '上海市虹口区'
from dual;
insert into EMP
select 4, '峡谷之巅', 4580, '上海市闵行区'
from dual;
insert into EMP
select 5, '黑色玫瑰', 5580, '上海市静安区'
from dual;

PLSQL编程

概念

PLSQL是Oracle对sql语言的过程化扩展，指在SQL命令语言中增加了过程处理语句（如分支、循环等），使SQL语言具有过程处理能力。

程序结构

PL/SQL可以分为三个部分：声明部分、可执行部分、异常处理部分。

其中DECLARE部分用来声明变量或游标（结果集类型变量），如果程序中无变量声明可以省略掉。

sql 复制代码 
DECLARE
    -- 声明变量、游标。
    I INTEGER;
BEGIN
    -- 执行语句

    -- 异常处理

END;

运行程序

在DataGrip中运行

DBMS_OUTPUT为Oracle内置程序包

sql 复制代码 
BEGIN
    -- 打印hello world
    DBMS_OUTPUT.PUT_LINE('hello world');
END;
DataGrip设置控制台输出打印内容

双击Shift搜索"dbms"，将开关打开

在sqlplus中运行

在sqlplus中执行PLSQL程序需要在程序最后添加一个'/' 符号，以标识程序的结束。

bash 复制代码 
sqlplus # 使用账号密码登录
BEGIN
    -- 打印hello world
    DBMS_OUTPUT.PUT_LINE('hello world');
END;
/
sqlplus设置控制台输出打印内容

执行结束后并未显示输出的结果，默认情况下，输出选项是关闭状态的，我们需要开启一下。

bash 复制代码 
set serveroutput on

变量

  1. 普通数据类型（char,varchar2, date, number, boolean, long）
  2. 特殊变量类型（引用型变量、记录型变量）

声明变量的方式为

变量名 变量类型（变量长度）

例如：v_name varchar2(20);

普通变量
  1. 直接赋值语句，使用:=赋值

变量 := 值

例如：v_name := 'honey'

  1. 语句赋值，使用select ... into ... 赋值

select 值 into 变量

例如：select 'honey' into v_name

sql 复制代码 
-- 打印人员个人信息，包括：姓名、薪水、地址
DECLARE
    -- 姓名
    V_NAME    VARCHAR2(20) := 'honey'; -- 声明变量直接赋值
    -- 薪水
    V_SALARY  NUMBER;
    -- 地址
    V_ADDRESS VARCHAR2(200);
BEGIN
    -- 在程序中直接赋值
    V_SALARY := 1580;
    -- 语句赋值
    SELECT '上海市徐汇区' INTO V_ADDRESS FROM DUAL;
    -- 打印变量
    DBMS_OUTPUT.PUT_LINE('姓名：' || V_NAME || '，薪水：' || V_SALARY || '，地址：' || V_ADDRESS);
END;
引用型变量

变量的类型和长度取决于表中字段的类型和长度

通过表名.列名%TYPE 指定变量的类型和长度

例如：v_name emp.ename%TYPE

sql 复制代码 
-- 查询emp表中2号员工的个人信息，并打印姓名和薪水
DECLARE
    -- 姓名
    V_NAME   EMP.NAME%TYPE;
    -- 薪水
    V_SALARY EMP.SALARY%TYPE;
BEGIN
    -- 查询表中的姓名和薪水并赋值给变量
    SELECT NAME, SALARY INTO V_NAME, V_SALARY FROM EMP WHERE NO = 2;
    -- 打印变量
    DBMS_OUTPUT.PUT_LINE('姓名：' || V_NAME || '，薪水：' || V_SALARY);
END;

引用型变量的好处：

使用普通变量定义方式，需要知道表中列的类型，而使用引用类型，不需要考虑列的类型，使用%TYPE是非常好的编程风格，因为它使得PL/SQL更加灵活，更加适应于对数据库定义的更新。

记录型变量

接收表中的一整行记录，相当于Java中的一个对象。

变量名 表名%ROWTYPE

例如：v_emp emp%rowtype;

sql 复制代码 
-- 查询emp表中3号员工的个人信息，并打印姓名和薪水
DECLARE
    -- 记录型变量
    V_EMP EMP%ROWTYPE;
BEGIN
    -- 记录型变量默认接收表中的一行数据，不能指定字段。
    SELECT * INTO V_EMP FROM EMP WHERE NO = 3;
    -- 打印变量，通过变量名.属性的方式获取变量中的值
    DBMS_OUTPUT.PUT_LINE('姓名：' || V_EMP.NAME || '，薪水：' || V_EMP.SALARY);
END;

流程控制

条件分支
sql 复制代码 
BEGIN
    IF 条件1 THEN 执行1
    ELSIF 条件2 THEN 执行2
    ELSE 执行3
    END IF;
END;
sql 复制代码 
-- 判断emp表中的记录数所在的数值范围
DECLARE
    -- emp表中的记录数
    V_COUNT NUMBER;
BEGIN
    -- 查询emp表中的记录数赋值给变量
    SELECT COUNT(1) INTO V_COUNT FROM EMP;
    -- 判断打印
    IF V_COUNT > 20 THEN
        DBMS_OUTPUT.PUT_LINE('EMP表中的记录数超过了20条为：' || V_COUNT || '条。');
    ELSIF V_COUNT >= 10 THEN
        DBMS_OUTPUT.PUT_LINE('EMP表中的记录数在10~20条之间为：' || V_COUNT || '条。');
    ELSE
        DBMS_OUTPUT.PUT_LINE('EMP表中的记录数在10条以下为：' || V_COUNT || '条。');
    END IF;
END;
循环
sql 复制代码 
BEGIN
    LOOP
        EXIT WHEN 退出循环条件
    END LOOP;
END;
sql 复制代码 
-- 打印1-10
DECLARE
    -- 声明循环变量并赋初值
    V_NUM NUMBER := 1;
BEGIN
    LOOP
        EXIT WHEN V_NUM > 10;
        DBMS_OUTPUT.PUT_LINE(V_NUM);
        -- 循环变量自增
        V_NUM := V_NUM + 1;
    END LOOP;
END;

游标

概念

用于临时存储一个查询返回的多行数据（结果集），通过遍历游标，可以逐行访问处理该结果集的数据。

游标的使用方式：声明--->打开--->读取--->关闭

语法

sql 复制代码 
游标的声明：
CURSOR 游标名[(参数列表)] IS 查询语句;
游标的打开：
OPEN 游标名;
游标的取值：
FETCH 游标名 INTO 变量列表;
游标的关闭：
CLOSE 游标名;

游标的属性

游标的属性 返回值类型 说明
%ROWCOUNT 整型 获得FETCH语句返回的数据行数
%FOUND 布尔型 最近的FETCH语句返回一行数据则为真，否则为假
%NOTFOUND 布尔型 与%FOUND属性返回值相反
%ISOPEN 布尔型 游标已经打开时值为真，否则为假

其中%NOTFOUND是在游标中找不到元素的时候返回TRUE，通常用来判断退出循环。

创建与使用

sql 复制代码 
-- 使用游标查询emp表中所有员工的姓名和工资，并将其依次打印出来
DECLARE
    -- 声明游标
    CURSOR C_EMP IS
        SELECT NAME, SALARY
        FROM EMP;
    -- 声明变量用来接收游标中的元素
    V_NAME   EMP.NAME%TYPE;
    V_SALARY EMP.SALARY%TYPE;
BEGIN
    -- 打开游标
    OPEN C_EMP;
    -- 遍历游标中的值
    LOOP
        -- 通过FETCH语句获取游标中的值并赋值给变量
        FETCH C_EMP
            INTO V_NAME, V_SALARY;
        -- 判断是否有值，有值打印，没有则退出循环
        EXIT WHEN C_EMP%NOTFOUND;
        DBMS_OUTPUT.PUT_LINE('姓名：' || V_NAME || '，薪水：' || V_SALARY);
    END LOOP;
    -- 关闭游标
    CLOSE C_EMP;
END;

带参数的游标

sql 复制代码 
-- 使用游标查询并打印4号员工的姓名和薪资
DECLARE
    -- 声明游标传递参数
    CURSOR C_EMP(V_NO EMP.NO%TYPE) IS
        SELECT NAME, SALARY
        FROM EMP
        WHERE NO = V_NO;
    -- 声明变量用来接收游标中的元素
    V_NAME   EMP.NAME%TYPE;
    V_SALARY EMP.SALARY%TYPE;
BEGIN
    -- 打开游标并传递参数
    OPEN C_EMP(4);
    -- 遍历游标中的值
    LOOP
        -- 通过FETCH语句获取游标中的值并赋值给变量
        FETCH C_EMP
            INTO V_NAME, V_SALARY;
        -- 判断是否有值，有值打印，没有则退出循环
        EXIT WHEN C_EMP%NOTFOUND;
        DBMS_OUTPUT.PUT_LINE('姓名：' || V_NAME || '，薪水：' || V_SALARY);
    END LOOP;
    -- 关闭游标
    CLOSE C_EMP;
END;

存储过程

概念

上述PLSQL程序可以进行表的操作、判断、循环逻辑处理的工作，但无法重复调用。

将一个个PLSQL的业务处理过程存储起来进行复用，这些被存储起来的PLSQL程序称之为存储过程。

作用

  1. 在开发程序中，为了一个特定的业务功能，会向数据库进行多次连接关闭（连接和关闭很耗费资源），需要对数据库进行多次I/O读写，性能比较低。如果把这些业务放到PLSQL中，在应用程序中只需要调用PLSQL就可以做到连接关闭一次数据库就可以实现我们的业务，可以大大提高效率；
  2. ORACLE官方给的建议：能够让数据库操作的不要放在程序中。在数据库中实现基本上不会出现错误，在程序中操作可能会存在错误（如果在数据库中操作数据，可以有一定的日志恢复等功能）

语法

sql 复制代码 
CREATE OR REPLACE PROCEDURE 过程名称[(参数列表)] IS
BEGIN

END [过程名称];

无参存储过程

创建
sql 复制代码 
-- 通过调用存储过程打印hello world
CREATE OR REPLACE PROCEDURE P_HELLO IS
BEGIN
    DBMS_OUTPUT.PUT_LINE('hello world');
END P_HELLO;
调用
在DataGrip中调用
sql 复制代码 
BEGIN
    -- 直接输入调用存储过程的名称
    P_HELLO;
END;
在sqlplus中调用
sql 复制代码 
set serveroutput on
BEGIN
    -- 直接输入调用存储过程的名称
    P_HELLO;
END;
/
sql 复制代码 
-- 使用EXEC命令调用
exec P_HELLO;

有输入参数的存储过程

sql 复制代码 
-- 查询并打印某个员工（如5号员工）的姓名和薪水
CREATE OR REPLACE PROCEDURE P_QUERY(I_NO IN EMP.NO%TYPE) IS
    -- 声明变量接收查询结果
    V_NAME   EMP.NAME%TYPE;
    V_SALARY EMP.SALARY%TYPE;
BEGIN
    -- 根据用户传递的员工号查询姓名和薪水
    SELECT NAME, SALARY INTO V_NAME, V_SALARY FROM EMP WHERE NO = I_NO;
    -- 打印结果
    DBMS_OUTPUT.PUT_LINE('姓名：' || V_NAME || '，薪水：' || V_SALARY);
END P_QUERY;
sql 复制代码 
BEGIN
    P_QUERY(5);
END;

有输出参数的存储过程

sql 复制代码 
-- 查询并打印某个员工（如5号员工）的姓名和薪水
CREATE OR REPLACE PROCEDURE P_QUERY_OUT(
    I_NO IN EMP.NO%TYPE,
    O_NAME OUT EMP.NAME%TYPE,
    O_SALARY OUT EMP.SALARY%TYPE
) IS
BEGIN
    SELECT NAME, SALARY INTO O_NAME, O_SALARY FROM EMP WHERE NO = I_NO;
END P_QUERY_OUT;
sql 复制代码 
DECLARE
    --声明一个变量接受存储过程的输出参数
    V_NAME   EMP.NAME%TYPE;
    V_SALARY EMP.SALARY%TYPE;
BEGIN
    P_QUERY_OUT(5, V_NAME, V_SALARY);
    DBMS_OUTPUT.PUT_LINE('姓名：' || V_NAME || '，薪水：' || V_SALARY);
END;
相关推荐
派可数据BI可视化11 分钟前
连锁餐饮行业数据可视化分析方案
大数据·数据库·数据仓库·数据分析·商业智能bi
dbcat官方14 分钟前
1.微服务灰度发布(方案设计)
java·数据库·分布式·微服务·中间件·架构
青年有志22 分钟前
深入浅出 MyBatis | CRUD 操作、配置解析
数据库·tomcat·mybatis
数据的世界0125 分钟前
SQL创建和操纵表
数据库·sql
Echo flower28 分钟前
mybatis-plus自动填充时间的配置类实现
java·数据库·mybatis
李匠202429 分钟前
大数据学习之Redis 缓存数据库二，Scala分布式语言一
大数据·数据库·缓存
冰镇毛衣1 小时前
4.3 数据库HAVING语句
数据库·sql·mysql
Crossoads1 小时前
【汇编语言】外中断（一）—— 外中断的魔法：PC机键盘如何触发计算机响应
android·开发语言·数据库·深度学习·机器学习·计算机外设·汇编语言
凡人的AI工具箱2 小时前
每天40分玩转Django：Django缓存
数据库·人工智能·后端·python·缓存·django
软茸兔2 小时前
笔记：一次oracle 集群日志维护
数据库·笔记·oracle
热门推荐
01大模型国产化适配7-华为昇腾LLM落地可选解决方案（MindFormers、ModelLink、MindIE）02Ubuntu 20.04使用Livox mid 360 测试 FAST_LIO03玄机平台应急响应—webshell查杀04电赛2024年H题智能小车基于MSPM0G3507主控MCU（利用8路灰度加上MPU6050的解决方式）具体项目报告05组基轨迹建模 GBTM的介绍与实现（Stata 或 R）06支付宝短视频平台创作分成激励项目07怎么找小红书美食探店博主合作？08【一文读懂】NTN（非地面网络）技术介绍09优化手机性能，解决卡顿问题：关闭这3个微信开关，释放内存空间10STM32 无法烧录