arduino平台读取鼠标光电传感器

鼠标坏掉了,大抵是修不好了。(全剧终---)

但是爱动手的小明不会浪费这个鼠标,确认外观没有明显烧毁痕迹后,尝试从电路板上利用光电传感器进行位移的测量,光电传感器(型号:FCT3065)找不到datasheet,但查到内核仿的是PAW3205, 因此只需要参考后者的datasheet即可。

通过电路板的led找到LED引脚,确定引脚信息,开始操作

首先去掉鼠标主控芯片,然后飞线将vdd连接到电源正极,注意供电不能高于3.6v,再焊接4根杜邦线,引出SDIO、SCLK、电源正负极即可,盖上盖子,测试!

复制代码
/*
   Program to interface FCT3065-XY Optical Mouse
   Sensor with Arduino.

   This code detects when mouse is moved and also
   prints the change in x direction and change in y
   direction in the serial monitor.

   Author: Vineet Sukhthanker
   Date: 6 October 2020


*/

//Register Addresses from datasheet
#define PROD_ID1 0x00
#define PROD_ID2 0x01
#define MOTION_STATUS 0X02
#define DEL_X 0x03
#define DEL_Y 0x04
#define OP_MODE 0x05
#define CONF 0x06
#define IMG_QUALITY 0x07
#define OP_STATE 0x08
#define W_PROTECT 0x09
#define SLEEP1_SET 0x0A
#define ENTER_TIME 0x0B
#define SLEEP2_SET 0x0C
#define IMG_THRESHOLD 0x0D
#define IMG_RECOG 0x0E

const int SCLK = 13;
const int SDIO = 12;

byte noSleep = 0xA0;

int i = 0;
void setup() {
  Serial.begin(115200);
  pinMode (SCLK, OUTPUT);
  mouseInit();

  byte prodId1 = readRegister(PROD_ID1);
  Serial.print((prodId1 == 0x31) ? "\nDevice OK" : "\nUnknown Device"); // checks for product ID
  Serial.print(prodId1);
}

void loop() {
  int motion = readRegister(MOTION_STATUS); // read motion status register
  // if(motion==0x81){
  Serial.print("\nMoved!");
  Serial.print(motion);
  int8_t delta_x = readRegister(DEL_X); // read delta x register
  int8_t delta_y = readRegister(DEL_Y); // read delta y register
  Serial.print("\nX:");

  Serial.print(delta_x);

  Serial.print(" Y:");

  Serial.print(delta_y);
  //}
  delay(1000);
}

void mouseInit(void) // function to initialize optical sensor.
{
  digitalWrite(SCLK, HIGH);
  digitalWrite(SCLK, LOW);
  delayMicroseconds(1); // tRESYNC = 1us (mentioned in datasheet)
  digitalWrite(SCLK, HIGH);
  delay(320); // tSIWTT = 320ms (mentioned in datasheet)
  digitalWrite(SCLK, LOW);
  writeRegister(OP_MODE, noSleep); // disable sleep mode
}

byte readRegister(byte address) {
  pinMode (SDIO, OUTPUT);

  for (byte i = 128; i > 0 ; i >>= 1) {
    digitalWrite (SCLK, LOW);
    digitalWrite (SDIO, (address & i) != 0 ? HIGH : LOW);
    digitalWrite (SCLK, HIGH);
  }

  pinMode (SDIO, INPUT);

  delayMicroseconds(3); // tHOLD = 3us (mentioned in datasheet)

  byte res = 0;
  for (byte i = 128; i > 0 ; i >>= 1) {
    digitalWrite (SCLK, LOW);
    digitalWrite (SCLK, HIGH);
    if ( digitalRead (SDIO) == HIGH )
      res |= i;
  }

  delayMicroseconds(3); // tHOLD = 3us min. (mentioned in datasheet)

  return res;
}

void writeRegister(byte address, byte data) {
  address |= 0x80; // MSB indicates write mode.
  pinMode (SDIO, OUTPUT);

  for (byte i = 128; i > 0 ; i >>= 1) {
    digitalWrite (SCLK, LOW);
    digitalWrite (SDIO, (address & i) != 0 ? HIGH : LOW);
    digitalWrite (SCLK, HIGH);
  }

  for (byte i = 128; i > 0 ; i >>= 1) {
    digitalWrite (SCLK, LOW);
    digitalWrite (SDIO, (data & i) != 0 ? HIGH : LOW);
    digitalWrite (SCLK, HIGH);
  }

  delayMicroseconds(100);
}

效果如图,x和y坐标分别向下向右为正,寄存器补码形式存储8位位移量

大合照(或许旋转编码器还再可以玩一玩)

参考

如何优雅的DIY鼠标?

FCT3065-XY_MouseSensor。

相关推荐
希和20279 小时前
江科大 51 单片机笔记:DS18B20 温度传感器 + LCD1602 显示代码详解
笔记·单片机·mongodb
不脱发的程序猿12 小时前
ESP32制作加热杯垫
嵌入式硬件·物联网·esp32·语音识别
Zwawa14 小时前
陀螺仪数据为什么看起来总在动:零偏、噪声和零漂
c语言·单片机·嵌入式
元器件BOM超人18 小时前
GD32F130G8U6TR QFN-28 兆易创新超值型Cortex-M3 MCU 解析
单片机·嵌入式硬件
硅农程序猿18 小时前
SOC 物理实现: RTL2GDS 系列(二)—Innovus 初始化
人工智能·嵌入式硬件·硬件架构
希和202719 小时前
51 单片机学习笔记:LCD1602、独立按键、I2C 与 AT24C02 掉电存储(江科大课程小白笔记)
笔记·单片机·学习
碧海银沙音频科技研究院21 小时前
BP寻呼机原理
人工智能·嵌入式硬件
希和20272 天前
江科大 51 单片机课程笔记:DS1302 实时时钟 + LCD1602 可调电子钟(小白逐行讲解)
笔记·单片机·嵌入式硬件
女神下凡2 天前
芯参谋(107):杰理AC_中科蓝讯_开发指南
linux·服务器·网络·单片机·嵌入式硬件
shimly1234562 天前
(done) 嵌入式硬件电路图 (11) 用 AI 看电路图与总结
嵌入式硬件