STM32_标准库启动文件startup_stm32f10x_hd.s详解

文章目录

• 一、功能
• 二、系统复位后的工作
• 三、文件详细解析
• 四、ARM汇编指令
• 五、启动文件代码详解
• • [   1、Stack---栈](#   1、Stack—栈)
  • [   2、Heap堆](#   2、Heap堆)
  • [   3、向量表](#   3、向量表)
  • [   4、复位程序](#   4、复位程序)
  • [   5、中断服务程序](#   5、中断服务程序)
  • [   6、用户堆栈初始化](#   6、用户堆栈初始化)

一、功能

初始化堆栈指针SP;

初始化程序计数器指针PC;

设置堆、栈的大小;

初始化中断向量表;

配置外部SRAM作为数据存储器（这个由用户配置，一般的开发板可没有外部SRAM）;

调用SystemIni() 函数配置STM32的系统时钟。

设置C库的分支入口"__main"（最终用来调用main函数）;

二、系统复位后的工作

	;Reset handler
	Reset_Handler    PROC
	                EXPORT  Reset_Handler     [WEAK]
	    IMPORT  SystemInit
	    IMPORT  __main
	
	        LDR     R0, =SystemInit
	        BLX     R0
	        LDR     R0, =__main
	        BX      R0
	        ENDP

开头

的是程序注释，在汇编里面注释用的是";"，相当于 C 语言的"//"注释符。

第二行

是定义了一个子程序：Reset_Handler。PROC 是子程序定义伪指令。这里就相当于C语言里定义了一个函数，函数名为Reset_Handler。

第三行

EXPORT 表示 Reset_Handler 这个子程序可供其他模块调用。相当于C语言的函数声明。关键字[WEAK] 表示弱定义， 如果编译器发现在别处定义了同名的函数，则在链接时用别处的地址进行链接，如果其它地方没有定义，编译器也不报错，以此处地址进行链接。

第四行和第五行

IMPORT 说明 SystemInit 和__main 这两个标号在其他文件，在链接的时候需要到其他文件去寻找。 相当于C语言中，从其它文件引入函数声明。以便下面对外部函数进行调用。

SystemInit 需要由我们自己实现，即我们要编写一个具有该名称的函数，用来初始化 STM32 芯片的时钟，一般包括初始化AHB、APB等各总线的时钟， 需要经过一系列的配置STM32才能达到稳定运行的状态。其实这个函数在固件库里面有提供，官方已经为我们写好。

__main 其实不是我们定义的(不要与C语言中的main函数混淆)，这是一个C库函数，当编译器编译时，只要遇到这个标号就会定义这个函数， 该函数的主要功能是：负责初始化栈、堆，配置系统环境，并在函数的最后调用用户编写的 main 函数，从此来到 C 的世界。

第六行

把 SystemInit 的地址加载到寄存器 R0。

第七行

程序跳转到 R0 中的地址执行程序，即执行SystemInit函数的内容。

第八行

把__main 的地址加载到寄存器 R0。

第九行

程序跳转到 R0 中的地址执行程序，即执行__main函数，执行完毕之后就去到我们熟知的 C 世界，进入main函数。

第十行

表示子程序的结束。

三、文件详细解析

	
	;******************** (C) COPYRIGHT 2011 STMicroelectronics ********************
	;* File Name          : startup_stm32f10x_hd.s
	;* Author             : MCD Application Team
	;* Version            : V3.5.0
	;* Date               : 11-March-2011
	;* Description        : STM32F10x High Density Devices vector table for MDK-ARM 
	;*                      toolchain. 
	;*                      This module performs:
	;*                      - 初始化堆栈指针SP
	;*                      - 初始化PC指针
	;*                      - 初始化中断向量表
	;*                      - 配置系统时钟
	;*                      - 调用C库函数_main，最终去到C的世界
	;*                      After Reset the CortexM3 processor is in Thread mode,
	;*                      priority is Privileged, and the Stack is set to Main.
	;* <<< Use Configuration Wizard in Context Menu >>>   
	;*******************************************************************************
	; THE PRESENT FIRMWARE WHICH IS FOR GUIDANCE ONLY AIMS AT PROVIDING CUSTOMERS
	; WITH CODING INFORMATION REGARDING THEIR PRODUCTS IN ORDER FOR THEM TO SAVE TIME.
	; AS A RESULT, STMICROELECTRONICS SHALL NOT BE HELD LIABLE FOR ANY DIRECT,
	; INDIRECT OR CONSEQUENTIAL DAMAGES WITH RESPECT TO ANY CLAIMS ARISING FROM THE
	; CONTENT OF SUCH FIRMWARE AND/OR THE USE MADE BY CUSTOMERS OF THE CODING
	; INFORMATION CONTAINED HEREIN IN CONNECTION WITH THEIR PRODUCTS.
	;*******************************************************************************
	
	;1-栈======================================
	; Amount of memory (in bytes) allocated for Stack
	; Tailor this value to your application needs
	; <h> 栈配置，用于变量，函数调用
	;   <o> Stack Size (in Bytes) <0x0-0xFFFFFFFF:8>
	; </h>
	
	Stack_Size      EQU     0x00000400    ; 1KB
	
	                AREA    STACK, NOINIT, READWRITE, ALIGN=3
	Stack_Mem       SPACE   Stack_Size
	__initial_sp
	
	;2-堆======================================                                                  
	; <h> 堆配置，用于malloc等函数的动态内存分配
	;   <o>  Heap Size (in Bytes) <0x0-0xFFFFFFFF:8>
	; </h>
	
	Heap_Size       EQU     0x00000200   ;512B
	
	                AREA    HEAP, NOINIT, READWRITE, ALIGN=3
	__heap_base
	Heap_Mem        SPACE   Heap_Size
	__heap_limit
	
	                PRESERVE8    ;当前堆栈8字节对齐
	                THUMB        ;兼容 THUMB 指令，老的指令，16bit，现在Cortex-M3的都是THUMB-2指令，兼容16/32位
	
	;3-向量表，存的是中断服务函数的名称，即地址
	; Vector Table Mapped to Address 0 at Reset，这里的0地址指的是FLASH的起始地址
	                AREA    RESET, DATA, READONLY
	                EXPORT  __Vectors
	                EXPORT  __Vectors_End
	                EXPORT  __Vectors_Size
	
	__Vectors       DCD     __initial_sp               ; Top of Stack
	                DCD     Reset_Handler              ; Reset Handler
	                DCD     NMI_Handler                ; NMI Handler
	                DCD     HardFault_Handler          ; Hard Fault Handler
	                DCD     MemManage_Handler          ; MPU Fault Handler
	                DCD     BusFault_Handler           ; Bus Fault Handler
	                DCD     UsageFault_Handler         ; Usage Fault Handler
	                DCD     0                          ; Reserved
	                DCD     0                          ; Reserved
	                DCD     0                          ; Reserved
	                DCD     0                          ; Reserved
	                DCD     SVC_Handler                ; SVCall Handler
	                DCD     DebugMon_Handler           ; Debug Monitor Handler
	                DCD     0                          ; Reserved
	                DCD     PendSV_Handler             ; PendSV Handler
	                DCD     SysTick_Handler            ; SysTick Handler
	
	                ; External Interrupts
	                DCD     WWDG_IRQHandler            ; Window Watchdog
	                DCD     PVD_IRQHandler             ; PVD through EXTI Line detect
	                DCD     TAMPER_IRQHandler          ; Tamper
	                DCD     RTC_IRQHandler             ; RTC
	                DCD     FLASH_IRQHandler           ; Flash
	                DCD     RCC_IRQHandler             ; RCC
	                DCD     EXTI0_IRQHandler           ; EXTI Line 0
	                DCD     EXTI1_IRQHandler           ; EXTI Line 1
	                DCD     EXTI2_IRQHandler           ; EXTI Line 2
	                DCD     EXTI3_IRQHandler           ; EXTI Line 3
	                DCD     EXTI4_IRQHandler           ; EXTI Line 4
	                DCD     DMA1_Channel1_IRQHandler   ; DMA1 Channel 1
	                DCD     DMA1_Channel2_IRQHandler   ; DMA1 Channel 2
	                DCD     DMA1_Channel3_IRQHandler   ; DMA1 Channel 3
	                DCD     DMA1_Channel4_IRQHandler   ; DMA1 Channel 4
	                DCD     DMA1_Channel5_IRQHandler   ; DMA1 Channel 5
	                DCD     DMA1_Channel6_IRQHandler   ; DMA1 Channel 6
	                DCD     DMA1_Channel7_IRQHandler   ; DMA1 Channel 7
	                DCD     ADC1_2_IRQHandler          ; ADC1 & ADC2
	                DCD     USB_HP_CAN1_TX_IRQHandler  ; USB High Priority or CAN1 TX
	                DCD     USB_LP_CAN1_RX0_IRQHandler ; USB Low  Priority or CAN1 RX0
	                DCD     CAN1_RX1_IRQHandler        ; CAN1 RX1
	                DCD     CAN1_SCE_IRQHandler        ; CAN1 SCE
	                DCD     EXTI9_5_IRQHandler         ; EXTI Line 9..5
	                DCD     TIM1_BRK_IRQHandler        ; TIM1 Break
	                DCD     TIM1_UP_IRQHandler         ; TIM1 Update
	                DCD     TIM1_TRG_COM_IRQHandler    ; TIM1 Trigger and Commutation
	                DCD     TIM1_CC_IRQHandler         ; TIM1 Capture Compare
	                DCD     TIM2_IRQHandler            ; TIM2
	                DCD     TIM3_IRQHandler            ; TIM3
	                DCD     TIM4_IRQHandler            ; TIM4
	                DCD     I2C1_EV_IRQHandler         ; I2C1 Event
	                DCD     I2C1_ER_IRQHandler         ; I2C1 Error
	                DCD     I2C2_EV_IRQHandler         ; I2C2 Event
	                DCD     I2C2_ER_IRQHandler         ; I2C2 Error
	                DCD     SPI1_IRQHandler            ; SPI1
	                DCD     SPI2_IRQHandler            ; SPI2
	                DCD     USART1_IRQHandler          ; USART1
	                DCD     USART2_IRQHandler          ; USART2
	                DCD     USART3_IRQHandler          ; USART3
	                DCD     EXTI15_10_IRQHandler       ; EXTI Line 15..10
	                DCD     RTCAlarm_IRQHandler        ; RTC Alarm through EXTI Line
	                DCD     USBWakeUp_IRQHandler       ; USB Wakeup from suspend
	                DCD     TIM8_BRK_IRQHandler        ; TIM8 Break
	                DCD     TIM8_UP_IRQHandler         ; TIM8 Update
	                DCD     TIM8_TRG_COM_IRQHandler    ; TIM8 Trigger and Commutation
	                DCD     TIM8_CC_IRQHandler         ; TIM8 Capture Compare
	                DCD     ADC3_IRQHandler            ; ADC3
	                DCD     FSMC_IRQHandler            ; FSMC
	                DCD     SDIO_IRQHandler            ; SDIO
	                DCD     TIM5_IRQHandler            ; TIM5
	                DCD     SPI3_IRQHandler            ; SPI3
	                DCD     UART4_IRQHandler           ; UART4
	                DCD     UART5_IRQHandler           ; UART5
	                DCD     TIM6_IRQHandler            ; TIM6
	                DCD     TIM7_IRQHandler            ; TIM7
	                DCD     DMA2_Channel1_IRQHandler   ; DMA2 Channel1
	                DCD     DMA2_Channel2_IRQHandler   ; DMA2 Channel2
	                DCD     DMA2_Channel3_IRQHandler   ; DMA2 Channel3
	                DCD     DMA2_Channel4_5_IRQHandler ; DMA2 Channel4 & Channel5
	__Vectors_End
	
	__Vectors_Size  EQU  __Vectors_End - __Vectors
	
	                AREA    |.text|, CODE, READONLY
	;4-复位程序，系统上电后第一个要执行的程序              
	; Reset handler
	Reset_Handler   PROC
	                EXPORT  Reset_Handler             [WEAK] ;弱定义
	                IMPORT  __main
	                IMPORT  SystemInit                       ;初始化系统时钟，由用户定义
	                LDR     R0, =SystemInit
	                BLX     R0               
	                LDR     R0, =__main                      ;C库函数，实现堆栈的初始化和调用c里面的main函数
	                BX      R0
	                ENDP
	;5-中断服务程序，全部为空，需要自己在C程序里面另外实现，但是函数名字必须跟这里的一样
	;如果不一样，则会执行这里的中断服务函数，即无限循环，出现这样的错误很难发现                
	; Dummy Exception Handlers (infinite loops which can be modified)
	
	NMI_Handler     PROC
	                EXPORT  NMI_Handler                [WEAK]
	                B       .
	                ENDP
	HardFault_Handler\
	                PROC
	                EXPORT  HardFault_Handler          [WEAK]
	                B       .
	                ENDP
	MemManage_Handler\
	                PROC
	                EXPORT  MemManage_Handler          [WEAK]
	                B       .
	                ENDP
	BusFault_Handler\
	                PROC
	                EXPORT  BusFault_Handler           [WEAK]
	                B       .
	                ENDP
	UsageFault_Handler\
	                PROC
	                EXPORT  UsageFault_Handler         [WEAK]
	                B       .
	                ENDP
	SVC_Handler     PROC
	                EXPORT  SVC_Handler                [WEAK]
	                B       .
	                ENDP
	DebugMon_Handler\
	                PROC
	                EXPORT  DebugMon_Handler           [WEAK]
	                B       .
	                ENDP
	PendSV_Handler  PROC
	                EXPORT  PendSV_Handler             [WEAK]
	                B       .
	                ENDP
	SysTick_Handler PROC
	                EXPORT  SysTick_Handler            [WEAK]
	                B       .
	                ENDP
	
	Default_Handler PROC
	
	                EXPORT  WWDG_IRQHandler            [WEAK]
	                EXPORT  PVD_IRQHandler             [WEAK]
	                EXPORT  TAMPER_IRQHandler          [WEAK]
	                EXPORT  RTC_IRQHandler             [WEAK]
	                EXPORT  FLASH_IRQHandler           [WEAK]
	                EXPORT  RCC_IRQHandler             [WEAK]
	                EXPORT  EXTI0_IRQHandler           [WEAK]
	                EXPORT  EXTI1_IRQHandler           [WEAK]
	                EXPORT  EXTI2_IRQHandler           [WEAK]
	                EXPORT  EXTI3_IRQHandler           [WEAK]
	                EXPORT  EXTI4_IRQHandler           [WEAK]
	                EXPORT  DMA1_Channel1_IRQHandler   [WEAK]
	                EXPORT  DMA1_Channel2_IRQHandler   [WEAK]
	                EXPORT  DMA1_Channel3_IRQHandler   [WEAK]
	                EXPORT  DMA1_Channel4_IRQHandler   [WEAK]
	                EXPORT  DMA1_Channel5_IRQHandler   [WEAK]
	                EXPORT  DMA1_Channel6_IRQHandler   [WEAK]
	                EXPORT  DMA1_Channel7_IRQHandler   [WEAK]
	                EXPORT  ADC1_2_IRQHandler          [WEAK]
	                EXPORT  USB_HP_CAN1_TX_IRQHandler  [WEAK]
	                EXPORT  USB_LP_CAN1_RX0_IRQHandler [WEAK]
	                EXPORT  CAN1_RX1_IRQHandler        [WEAK]
	                EXPORT  CAN1_SCE_IRQHandler        [WEAK]
	                EXPORT  EXTI9_5_IRQHandler         [WEAK]
	                EXPORT  TIM1_BRK_IRQHandler        [WEAK]
	                EXPORT  TIM1_UP_IRQHandler         [WEAK]
	                EXPORT  TIM1_TRG_COM_IRQHandler    [WEAK]
	                EXPORT  TIM1_CC_IRQHandler         [WEAK]
	                EXPORT  TIM2_IRQHandler            [WEAK]
	                EXPORT  TIM3_IRQHandler            [WEAK]
	                EXPORT  TIM4_IRQHandler            [WEAK]
	                EXPORT  I2C1_EV_IRQHandler         [WEAK]
	                EXPORT  I2C1_ER_IRQHandler         [WEAK]
	                EXPORT  I2C2_EV_IRQHandler         [WEAK]
	                EXPORT  I2C2_ER_IRQHandler         [WEAK]
	                EXPORT  SPI1_IRQHandler            [WEAK]
	                EXPORT  SPI2_IRQHandler            [WEAK]
	                EXPORT  USART1_IRQHandler          [WEAK]
	                EXPORT  USART2_IRQHandler          [WEAK]
	                EXPORT  USART3_IRQHandler          [WEAK]
	                EXPORT  EXTI15_10_IRQHandler       [WEAK]
	                EXPORT  RTCAlarm_IRQHandler        [WEAK]
	                EXPORT  USBWakeUp_IRQHandler       [WEAK]
	                EXPORT  TIM8_BRK_IRQHandler        [WEAK]
	                EXPORT  TIM8_UP_IRQHandler         [WEAK]
	                EXPORT  TIM8_TRG_COM_IRQHandler    [WEAK]
	                EXPORT  TIM8_CC_IRQHandler         [WEAK]
	                EXPORT  ADC3_IRQHandler            [WEAK]
	                EXPORT  FSMC_IRQHandler            [WEAK]
	                EXPORT  SDIO_IRQHandler            [WEAK]
	                EXPORT  TIM5_IRQHandler            [WEAK]
	                EXPORT  SPI3_IRQHandler            [WEAK]
	                EXPORT  UART4_IRQHandler           [WEAK]
	                EXPORT  UART5_IRQHandler           [WEAK]
	                EXPORT  TIM6_IRQHandler            [WEAK]
	                EXPORT  TIM7_IRQHandler            [WEAK]
	                EXPORT  DMA2_Channel1_IRQHandler   [WEAK]
	                EXPORT  DMA2_Channel2_IRQHandler   [WEAK]
	                EXPORT  DMA2_Channel3_IRQHandler   [WEAK]
	                EXPORT  DMA2_Channel4_5_IRQHandler [WEAK]
	
	        WWDG_IRQHandler
	        PVD_IRQHandler
	        TAMPER_IRQHandler
	        RTC_IRQHandler
	        FLASH_IRQHandler
	        RCC_IRQHandler
	        EXTI0_IRQHandler
	        EXTI1_IRQHandler
	        EXTI2_IRQHandler
	        EXTI3_IRQHandler
	        EXTI4_IRQHandler
	        DMA1_Channel1_IRQHandler
	        DMA1_Channel2_IRQHandler
	        DMA1_Channel3_IRQHandler
	        DMA1_Channel4_IRQHandler
	        DMA1_Channel5_IRQHandler
	        DMA1_Channel6_IRQHandler
	        DMA1_Channel7_IRQHandler
	        ADC1_2_IRQHandler
	        USB_HP_CAN1_TX_IRQHandler
	        USB_LP_CAN1_RX0_IRQHandler
	        CAN1_RX1_IRQHandler
	        CAN1_SCE_IRQHandler
	        EXTI9_5_IRQHandler
	        TIM1_BRK_IRQHandler
	        TIM1_UP_IRQHandler
	        TIM1_TRG_COM_IRQHandler
	        TIM1_CC_IRQHandler
	        TIM2_IRQHandler
	        TIM3_IRQHandler
	        TIM4_IRQHandler
	        I2C1_EV_IRQHandler
	        I2C1_ER_IRQHandler
	        I2C2_EV_IRQHandler
	        I2C2_ER_IRQHandler
	        SPI1_IRQHandler
	        SPI2_IRQHandler
	        USART1_IRQHandler
	        USART2_IRQHandler
	        USART3_IRQHandler
	        EXTI15_10_IRQHandler
	        RTCAlarm_IRQHandler
	        USBWakeUp_IRQHandler
	        TIM8_BRK_IRQHandler
	        TIM8_UP_IRQHandler
	        TIM8_TRG_COM_IRQHandler
	        TIM8_CC_IRQHandler
	        ADC3_IRQHandler
	        FSMC_IRQHandler
	        SDIO_IRQHandler
	        TIM5_IRQHandler
	        SPI3_IRQHandler
	        UART4_IRQHandler
	        UART5_IRQHandler
	        TIM6_IRQHandler
	        TIM7_IRQHandler
	        DMA2_Channel1_IRQHandler
	        DMA2_Channel2_IRQHandler
	        DMA2_Channel3_IRQHandler
	        DMA2_Channel4_5_IRQHandler
	                        B       .
	        
	                        ENDP
	
	                ALIGN
	;6-用户堆栈初始化，由C库函数_main来完成
	;*******************************************************************************
	; User Stack and Heap initialization
	;*******************************************************************************
	                 IF      :DEF:__MICROLIB       ;这个宏在IDE里面配置
	                
	                 EXPORT  __initial_sp
	                 EXPORT  __heap_base
	                 EXPORT  __heap_limit
	                
	                 ELSE
	                
	                 IMPORT  __use_two_region_memory ;这个函数需要用户自己实现
	                 EXPORT  __user_initial_stackheap
	                 
	__user_initial_stackheap  ; 
	
	                 LDR     R0, =  Heap_Mem
	                 LDR     R1, =(Stack_Mem + Stack_Size)
	                 LDR     R2, = (Heap_Mem +  Heap_Size)
	                 LDR     R3, = Stack_Mem
	                 BX      LR
	
	                 ALIGN
	
	                 ENDIF
	
	                 END
	
	;******************* (C) COPYRIGHT 2011 STMicroelectronics *****END OF FILE*****
	

四、ARM汇编指令

五、启动文件代码详解

1、Stack---栈

		Stack_Size      EQU     0x00000400
		
		                AREA    STACK, NOINIT, READWRITE, ALIGN=3
		Stack_Mem       SPACE   Stack_Size
		__initial_sp

开辟栈的大小为0X00000400（1KB），名字为STACK，NOINIT即不初始化，可读可写，8（2^3）字节对齐。

栈的作用是用于局部变量，函数调用，函数形参等的开销，栈的大小不能超过内部SRAM的大小。如果编写的程序比较大， 定义的局部变量很多，那么就需要修改栈的大小。如果某一天，你写的程序出现了莫名奇怪的错误，并进入了硬fault的时候，这时你就要考虑下是不是栈不够大，溢出了。

EQU：宏定义的伪指令，相当于等于，类似与C中的define。

AREA：告诉汇编器汇编一个新的代码段或者数据段。STACK表示段名，这个可以任意命名；NOINIT表示不初始化； READWRITE表示可读可写，ALIGN=3，表示按照2^3对齐，即8字节对齐。

SPACE：用于分配一定大小的内存空间，单位为字节。这里指定大小等于Stack_Size。

标号__initial_sp紧挨着SPACE语句放置，表示栈的结束地址，即栈顶地址，栈是由高向低生长的。

2、Heap堆

		Heap_Size     EQU     0x00000200
		
		            AREA    HEAP, NOINIT, READWRITE, ALIGN=3
		__heap_base
		Heap_Mem      SPACE   Heap_Size
		__heap_limit

开辟堆的大小为0X00000200（512字节），名字为HEAP，NOINIT即不初始化，可读可写，8（2^3）字节对齐。

__heap_base表示对的起始地址， __heap_limit表示堆的结束地址。堆是由低向高生长的，跟栈的生长方向相反。

堆主要用来动态内存的分配，像malloc()函数申请的内存就在堆上面。这个在STM32里面用的比较少。

PRESERVE8：指定当前文件的堆栈按照8字节对齐。

THUMB：表示后面指令兼容THUMB指令。THUBM是ARM以前的指令集，16bit，现在Cortex-M系列的都使用THUMB-2指令集， THUMB-2是32位的，兼容16位和32位的指令，是THUMB的超集。

3、向量表

		AREA    RESET, DATA, READONLY
		EXPORT  __Vectors
		EXPORT  __Vectors_End
		EXPORT  __Vectors_Size

定义一个数据段，名字为RESET，可读。 并声明 __Vectors、__Vectors_End和__Vectors_Size这三个标号具有全局属性，可供外部的文件调用。

EXPORT：声明一个标号可被外部的文件使用，使标号具有全局属性。如果是IAR编译器，则使用的是GLOBAL这个指令。

当内核响应了一个发生的异常后，对应的异常服务例程(ESR)就会执行。

为了决定 ESR 的入口地址， 内核使用了"向量表查表机制"。 这里使用一张向量表。

向量表其实是一个 WORD（ 32 位整数）数组，每个下标对应一种异常，该下标元素的值则是该 ESR的入口地址。

向量表在地址空间中的位置是可以设置的，通过 NVIC 中的一个重定位寄存器来指出向量表的地址。

在复位后，该寄存器的值为 0。因此， 在地址 0 （即FLASH 地址0）处必须包含一张向量表，用于初始时的异常分配。

要注意的是这里有个另类： 0 号类型并不是什么入口地址， 而是给出了复位后 MSP 的初值。

		__Vectors  DCD   __initial_sp        ;栈顶地址
		        DCD   Reset_Handler       ;复位程序地址
		        DCD   NMI_Handler
		        DCD   HardFault_Handler
		        DCD   MemManage_Handler
		        DCD   BusFault_Handler
		        DCD   UsageFault_Handler
		        DCD   0                    ; 0 表示保留
		        DCD   0
		        DCD   0
		        DCD   0
		        DCD   SVC_Handler
		        DCD   DebugMon_Handler
		        DCD   0
		        DCD   PendSV_Handler
		        DCD   SysTick_Handler
		
		
		;外部中断开始
		        DCD   WWDG_IRQHandler
		        DCD   PVD_IRQHandler
		        DCD   TAMPER_IRQHandler
		
		;限于篇幅，中间代码省略
		        DCD   DMA2_Channel2_IRQHandler
		        DCD   DMA2_Channel3_IRQHandler
		        DCD   DMA2_Channel4_5_IRQHandler
		__Vectors_End
		__Vectors_Size EQU __Vectors_End - __Vectors

__Vectors为向量表起始地址，__Vectors_End 为向量表结束地址，两个相减即可算出向量表大小。

向量表从FLASH的0地址开始放置，以4个字节为一个单位，地址0存放的是栈顶地址，0X04存放的是复位程序的地址，以此类推。

从代码上看，向量表中存放的都是中断服务函数的函数名，可我们知道C语言中的函数名就是一个地址。

DCD：分配一个或者多个以字为单位的内存，以四字节对齐，并要求初始化这些内存。在向量表中，DCD分配了一堆内存，并且以ESR的入口地址初始化它们。

4、复位程序

		AREA |.text|, CODE, READONLY
		定义一个名称为.text的代码段，可读。
		
		Reset_Handler PROC
		            EXPORT  Reset_Handler    [WEAK]
		            IMPORT  SystemInit
		            IMPORT  __main
		
		            LDR     R0, =SystemInit
		            BLX     R0
		            LDR     R0, =__main
		            BX      R0
		            ENDP

复位子程序是系统上电后第一个执行的程序，调用SystemInit函数初始化系统时钟，然后调用C库函数_mian，最终调用main函数去到C的世界。

WEAK：表示弱定义，如果外部文件优先定义了该标号则首先引用该标号，如果外部文件没有声明也不会出错。 这里表示复位子程序可以由用户在其他文件重新实现，这里并不是唯一的。

IMPORT：表示该标号来自外部文件，跟C语言中的EXTERN关键字类似。这里表示SystemInit和__main这两个函数均来自外部的文件。

SystemInit()是一个标准的库函数，在system_stm32f10x.c这个库文件总定义。主要作用是配置系统时钟，这里调用这个函数之后，单片机的系统时钟配被配置为72M。

__main是一个标准的C库函数，主要作用是初始化用户堆栈，并在函数的最后调用main函数去到C的世界。这就是为什么我们写的程序都有一个main函数的原因。

LDR、BLX、BX是CM4内核的指令，可在《CM3权威指南CnR2》第四章-指令集里面查询到，具体作用见下表：

5、中断服务程序

在启动文件里面已经帮我们写好所有中断的中断服务函数，跟我们平时写的中断服务函数不一样的就是这些函数都是空的， 真正的中断复服务程序需要我们在外部的C文件里面重新实现，这里只是提前占了一个位置而已。

如果我们在使用某个外设的时候，开启了某个中断，但是又忘记编写配套的中断服务程序或者函数名写错，那当中断来临的时， 程序就会跳转到启动文件预先写好的空的中断服务程序中，并且在这个空函数中无线循环，即程序就死在这里。

		NMI_Handler     PROC    ;系统异常
		                EXPORT  NMI_Handler           [WEAK]
		                B       .
		                ENDP
		
		;限于篇幅，中间代码省略
		SysTick_Handler PROC
		                EXPORT  SysTick_Handler       [WEAK]
		                B       .
		                ENDP
		
		Default_Handler PROC    ;外部中断
		                EXPORT  WWDG_IRQHandler       [WEAK]
		                EXPORT  PVD_IRQHandler        [WEAK]
		                EXPORT  TAMP_STAMP_IRQHandler [WEAK]
		
		;限于篇幅，中间代码省略
		LTDC_IRQHandler
		LTDC_ER_IRQHandler
		DMA2D_IRQHandler
		                B       .
		                ENDP
		B：跳转到一个标号。这里跳转到一个'.'，即表示无线循环。

6、用户堆栈初始化

		1 ALIGN：
		ALIGN：对指令或者数据存放的地址进行对齐，后面会跟一个立即数。缺省表示4字节对齐。
		
		代码
		;用户栈和堆初始化,由C库函数_main来完成
		IF      :DEF:__MICROLIB  ;这个宏在KEIL里面开启
		
		EXPORT  __initial_sp
		EXPORT  __heap_base
		EXPORT  __heap_limit
		
		ELSE
		
		IMPORT  __use_two_region_memory ; 这个函数由用户自己实现
		EXPORT  __user_initial_stackheap
		
		__user_initial_stackheap
		
		LDR     R0, =  Heap_Mem
		LDR     R1, =(Stack_Mem + Stack_Size)
		LDR     R2, = (Heap_Mem +  Heap_Size)
		LDR     R3, = Stack_Mem
		BX      LR
		
		ALIGN
		
		ENDIF

首先判断是否定义了__MICROLIB ，如果定义了这个宏则赋予标号__initial_sp（栈顶地址）、 __heap_base（堆起始地址）、__heap_limit（堆结束地址）全局属性，可供外部文件调用。 有关这个宏我们在KEIL里面配置，具体见图 使用微库。然后堆栈的初始化就由C库函数_main来完成。

如果没有定义__MICROLIB，则插入标号__use_two_region_memory，这个函数需要用户自己实现， 具体要实现成什么样，可在KEIL的帮助文档里面查询到， 具体见图 use_two_region_memory函数。

然后声明标号__user_initial_stackheap具有全局属性，可供外部文件调用，并实现这个标号的内容。

IF,ELSE,ENDIF：汇编的条件分支语句，跟C语言的if ,else类似

END：文件结束