Qt优雅的组织项目结构一（使用pri进行模块化配置）——————附带详细示例代码

文章目录

背景
- [1 使用pri](#1 使用pri)
- - [1.1 概念](#1.1 概念)
  - [1.2 应用场景](#1.2 应用场景)
  - [1.3 实践](#1.3 实践)
- 附录

背景

因为编写qt项目（早期为了快速快发，并没有进行分块），随着文件、代码量的越来越多，导致项目越来约难以管理。例如下面这个项目，光头文件就有几十个。因此需要把项目模块化来进行管理和开发，于是有了此篇文章。

1 使用pri

1.1 概念

.pri是Project Include（项目包含）文件的缩写。

本质：它的语法和 .pro（项目文件）完全一样，都是基于qmake语法。

作用：它不是一个独立的项目，而是一个配置容器。它被设计用来存放那些可以在多个项目之间共享的配置，比如源文件列表、头文件路径、库依赖等。

价值（模块化）：**当项目规模变大、团队协作开发时，可以更好的给项目模块化。**避免把所有配置都堆砌在 .pro 文件中，让项目结构更清晰，代码更易于复用。

1.2 应用场景

1. 模块化项目管理（推荐）
  当项目包含多个功能模块（如"网络模块"、"数据库模块"、"界面模块"）时，可以为每个模块创建一个.pri文件。
  做法：在每个模块文件夹下新建 network.pri、database.pri。
  好处：.pro 文件变得非常干净，只负责"组合"模块，而不关心模块内部的具体文件。如果要移除某个模块，只需注释掉一行 include。
1. 管理第三方库
  如果你的项目需要引入 OpenCV、Boost 等第三方库，或者你自己编译的静态库。
  做法：为每个第三方库创建一个 .pri 文件（如 opencv_config.pri）。
  好处：配置项（头文件路径、库文件路径、链接指令）被封装起来。当你把这个库分享给同事时，直接发一个 .pri 文件即可，无需口头指导如何配置环境。
1. 跨平台条件编译
  .pri 文件非常适合处理不同操作系统（Windows, Linux, macOS）下的差异。
  做法：在 .pri 文件中使用条件判断语句：

cpp 复制代码

win32 {
    LIBS += -lws2_32      # Windows 特有的库
    DEFINES += OS_WIN
}

unix:!macx {
    LIBS += -lpthread     # Linux 特有的库
    DEFINES += OS_LINUX
}

macx {
    LIBS += -framework Cocoa
    DEFINES += OS_MAC
}

这样，主.pro文件无需关心平台细节，直接include(platform.pri)即可。

1.3 实践

这是一个没有使用pri文件的项目:

pro文件的内容如下：

cpp 复制代码

QT       += core gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

CONFIG += c++17

# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

SOURCES += \
    main.cpp \
    mainwindow.cpp

HEADERS += \
    mainwindow.h

FORMS += \
    mainwindow.ui

# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target

现在我们对项目进行改造：

1，在项目的根目录下，新建一个interface文件夹，把UI相关的文件移到文件夹内；

创建前：

创建后：

2，在interface文件夹中，创建Interface.pri文件；
3，在pro文件中，添加如下内容;

cpp 复制代码

# 引入UI配置模块
include(./Interface/interface.pri)

把包含的文件代码修改为：

cpp 复制代码

SOURCES += \
    main.cpp
    # \
    # mainwindow.cpp

# HEADERS += \
#     mainwindow.h

# FORMS += \
#     mainwindow.ui

删除如下内容：

cpp 复制代码

# QT +=  gui

# greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

修改完成后的pro为：

cpp 复制代码

QT       += core

CONFIG += c++17

# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

SOURCES += \
    main.cpp

# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target

include(./Interface/interface.pri)

然后重写构建一下项目，将会变成如下的项目结构；

4，在Interface.pri中编写如下内容；

cpp 复制代码

# 指定头文件路径
INCLUDEPATH += $$PWD/include

# 指定依赖的 Qt 模块
QT +=  gui

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

# 添加源文件、头文件、UI文件
SOURCES += $$PWD/mainwindow.cpp

HEADERS += $$PWD/mainwindow.h

FORMS += $$PWD/mainwindow.ui

重写构建项目，项目结构将会变成：

这就相当于把UI模块剥离出来了。

5，现在需要在main函数中，使用UI模块中的代码；

cpp 复制代码

#include "interface/mainwindow.h"

#include <QApplication>

int main(int argc, char *argv[])
{
    QApplication a(argc, argv);
    MainWindow w;
    w.show();
    return a.exec();
}

如果包含头文件时，不想要interface的前缀，可以在pro文件中添加如下内容:

cpp 复制代码

INCLUDEPATH += $$PWD/interface

然后main函数的代码，就可以写成如下内容：

cpp 复制代码

#include "mainwindow.h"

#include <QApplication>

int main(int argc, char *argv[])
{
    QApplication a(argc, argv);
    MainWindow w;
    w.show();
    return a.exec();
}

至此带有pri分模块的项目，就构建完成了。

附录

完整的项目代码见此