UnityShader 植物被风吹弯效果

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "AchonorShader/Plant"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _BaseColor ("Base Color", Color) = (1, 1, 1, 1)
        _WindDirectionX("WindDirectionX", Range(-1,1)) = 0
        _WindDirectionZ("WindDirectionZ", Range(-1,1)) = 0
        //模型高度
        _ModelHeight("ModelHeight", Float) = 1
        //根的世界坐标
        _RootPosition("RootPosition", vector) = (0, 0, 0, 1)
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog
            #pragma enable_d3d11_debug_symbols
            
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float4 _BaseColor;
            float _WindDirectionX;
            float _WindDirectionZ;
            float _ModelHeight;
            float4 _RootPosition;

            v2f vert (appdata v)
            {
                v2f o;
                //_Matrix_M = UNITY_MATRIX_M;
                float4 worldPos = mul(UNITY_MATRIX_M, v.vertex);
                float4 rootWorldPos = _RootPosition;//mul(_Matrix_M, _RootOffset);
                float weight = (worldPos.y - rootWorldPos.y) / _ModelHeight;
                float weightX = (weight * _WindDirectionX) + 0.5 * 3.1415926f;
                float weightZ = -1 * ((weight * _WindDirectionZ) + 1.5 * 3.1415926f);
                float3x3 matrixX = float3x3(
                                        float3(sin(weightX), -cos(weightX), 0),
                                        float3(cos(weightX), sin(weightX), 0),
                                        float3(0, 0, 1));
                float3x3 matrixZ = float3x3(
                                        float3(1, 0, 0),
                                        float3(0, sin(weightZ), -cos(weightZ)),
                                        float3(0, cos(weightZ), sin(weightZ)));
                float3 offsetPos = worldPos - rootWorldPos;
                float4 newWorldPos = float4(mul(matrixZ, mul(matrixX, offsetPos)) + rootWorldPos, 1);
                
                o.vertex = mul(UNITY_MATRIX_VP, newWorldPos);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv) * _BaseColor;
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);
                return col;
            }
            ENDCG
        }
    }
}