《Unity Shader》10.1.3 反射

使用了反射效果的物体通常看起来就像镀了层金属。想要模拟反射效果很简单，我们只需要通过入射光线的方向和表面法线方向来计算反射方向，再利用反射方向对立方体纹理采样即可。在学习完本节后，我们可以得到类似图10.7中的效果。

（1）新建一个场景，在本书资源中，该场景名为Scene_10_1_3。我们替换掉Unity 5中场景默认的天空盒子，而把10.1.1节中创建的天空盒子材质拖曳到Window → Lighting → Skybox选项中（当然，我们也可以为摄像机添加Skybox组件来覆盖默认的天空盒子）。

(2）向场景中拖曳一个Teapot模型，并调整它的位置和10.1.2节中创建Cubemap_0时使用的空GameObject的位置相同。

https://github.com/candycat1992/Unity_Shaders_Book/blob/master/Assets/Models/Teapot.FBX

只要坐标一样就行

(3）新建一个材质，在本书资源中，该材质名为ReflectionMat，把材质赋给第2步中创建的Teapot模型。

(4）新建一个Unity Shader，在本书资源中，该Shader名为Chapter10-Reflection。把Chapter10-Reflection赋给第3步中创建的材质。

反射的实现非常简单。打开Chapter10-Reflection，删除原有的代码，进行如下关键修改。

(1）首先，我们声明了3个新的属性：

(2）我们在顶点着色器中计算了该顶点处的反射方向，这是通过使用CG的reflect函数来实现的：

(3）在片元着色器中，利用反射方向来对立方体纹理采样：

保存后返回场景，在材质面板中把Cubemap_0拖曳到Reflection Cubemap属性中，并调整其他参数，即可得到类似图10.7中的效果。

https://github.com/candycat1992/Unity_Shaders_Book/blob/master/Assets/Shaders/Chapter10/Chapter10-Reflection.shader

cs 复制代码

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Custom/Chapter10-Reflection"
{
    Properties {
        _Color ("Color Tint", Color) = (1, 1, 1, 1)
        _ReflectColor ("Reflection Color", Color) = (1, 1, 1, 1) //_ReflectColor用于控制反射颜色
        _ReflectAmount ("Reflect Amount", Range(0, 1)) = 1 //_ReflectAmount用于控制这个材质的反射程度
        _Cubemap ("Reflection Cubemap", Cube) = "_Skybox" {} //_Cubemap就是用于模拟反射的环境映射纹理。
    }

    SubShader {
        Tags { "RenderType"="Opaque" "Queue"="Geometry"} //渲染类型：不透明物体，渲染队列：几何体队列（默认值，2000），用于控制渲染顺序
        Pass {
            Tags { "LightMode"="ForwardBase" }
            CGPROGRAM
            #pragma multi_compile_fwdbase
            #pragma vertex vert
			#pragma fragment frag

            #include "Lighting.cginc"
			#include "AutoLight.cginc"

            fixed4 _Color;
			fixed4 _ReflectColor;
			fixed _ReflectAmount;
			samplerCUBE _Cubemap;

            struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};

            struct v2f {
				float4 pos : SV_POSITION;
				float3 worldPos : TEXCOORD0;
				fixed3 worldNormal : TEXCOORD1;
				fixed3 worldViewDir : TEXCOORD2;
				fixed3 worldRefl : TEXCOORD3;
				SHADOW_COORDS(4)
			};

            v2f vert(a2v v) {
				v2f o;
				
				o.pos = UnityObjectToClipPos(v.vertex);
				
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				
				o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);
				
				// Compute the reflect dir in world space
				o.worldRefl = reflect(-o.worldViewDir, o.worldNormal);
				
				TRANSFER_SHADOW(o);
				
				return o;
			}

            fixed4 frag(v2f i) : SV_Target {
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));		
				fixed3 worldViewDir = normalize(i.worldViewDir);		
				
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				
				fixed3 diffuse = _LightColor0.rgb * _Color.rgb * max(0, dot(worldNormal, worldLightDir));
				
				// Use the reflect dir in world space to access the cubemap
				fixed3 reflection = texCUBE(_Cubemap, i.worldRefl).rgb * _ReflectColor.rgb; //对立方体纹理的采样需要使用CG的texCUBE函数。 用于采样的参数仅仅是作为方向变量传递给texCUBE函数的，因此我们没有必要进行一次归一化的操作
				
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				
				// Mix the diffuse color with the reflected color
				fixed3 color = ambient + lerp(diffuse, reflection, _ReflectAmount) * atten; //lerp 线性插值函数，result = a + (b - a) * t
				
				return fixed4(color, 1.0);
			}
            ENDCG
        }
        
    }
    FallBack "Reflective/VertexLit"
}

调整main camera 要拍到 teapot，调整 teapot 的大小。就差不多了。