「Verilog学习笔记」非整数倍数据位宽转换8to12

专栏前言

本专栏的内容主要是记录本人学习Verilog过程中的一些知识点,刷题网站用的是牛客网

要实现8bit数据至12bit数据的位宽转换,必须要用寄存器将先到达的数据进行缓存。8bit数据至12bit数据,相当于1.5个输入数据拼接成一个输出数据,出于对资源的节省以及时序要求,采用1个8bit的寄存器(data_lock)进行数据缓存。

根据时序图,数据是在第二个数据到来之后输出,当仅有一个数据到来时,不产生输出,所以内部设计一个计数器(valid_cnt),用来指示数据接收状态。当检测到valid_in拉高时,valid_cnt加1,valid_cnt在0-2之间循环,valid_cnt复位值是0。当valid_cnt是1或2,且valid_in为高时,输出数据,valid_out拉高。

复制代码
`timescale 1ns/1ns

module width_8to12(
	input 				   clk 		,   
	input 			      rst_n		,
	input				      valid_in	,
	input	[7:0]			   data_in	,
 
 	output  reg			   valid_out,
	output  reg [11:0]   data_out
);
	reg [7:0] data_lock ; 
	reg [1:0] valid_cnt ; 

	always @ (posedge clk or negedge rst_n) begin
		if (~rst_n) data_lock <= 'd0 ; 
		else if (valid_in) data_lock <= data_in ; 
	end

	always @ (posedge clk or negedge rst_n) begin 
		if (~rst_n) valid_cnt <= 'd0 ; 
		else if (valid_in) 
			if (valid_cnt == 2'd2) valid_cnt <= 'd0 ; 
			else valid_cnt <= valid_cnt + 1'd1 ; 
	end

	always @ (posedge clk or negedge rst_n) begin 
		if (~rst_n) valid_out <= 'd0 ; 
		else if (valid_in && (valid_cnt == 2'd1 || valid_cnt == 2'd2)) valid_out <= 1'd1 ; 
		else valid_out <= 'd0 ;
	end

	always @ (posedge clk or negedge rst_n) begin 
		if (~rst_n) data_out <= 'd0 ; 
		else if (valid_in && valid_cnt == 2'd1) 
			data_out <= {data_lock, data_in[7:4]} ;
		else if (valid_in && valid_cnt == 2'd2) 
			data_out <= {data_lock[3:0], data_in} ; 
	end

endmodule
相关推荐
国科安芯14 小时前
FPGA上电偶发不启动:多轨电源时序、PGOOD与并联供电的FAE排查笔记——ASP4644S2B在星载智能处理板中的工程应用分析
笔记·单片机·嵌入式硬件·fpga开发·低轨卫星·抗辐射
星落梦生16 小时前
Docker学习(11)
学习·docker·容器
一条破秋裤1 天前
【1115】【多线程】【笔记】
前端·chrome·笔记
神明不懂浪漫1 天前
【第八章】多线程(一)
java·开发语言·经验分享·笔记
星恒随风1 天前
MySQL 从零入门(九):事务管理详解——ACID、COMMIT、ROLLBACK、SAVEPOINT 与四种隔离级别
linux·服务器·数据库·笔记·mysql
蒸蒸yyyyzwd1 天前
秋招操作系统错题本
笔记·八股
星恒随风1 天前
MySQL 从零入门(十一):视图与用户权限管理详解
linux·服务器·数据库·笔记·mysql
山楂树の1 天前
Java 泛型:泛型类、泛型方法、泛型接口与通配符
java·开发语言·笔记
重生之我是萧炎2 天前
PR安装教程,Adobe Premiere Pro安装教程(含安装包),仅供学习使用
学习·adobe
努力写代码的熊大2 天前
Linux 个人复盘博客 · 第六篇 Linux 进程间五种通信:匿名管道、命名管道、共享内存、消息队列与信号量
linux·经验分享·笔记