零知开源——STM32红外通信YS-IRTM红外编解码器集成灯控与显示系统

本项目基于零知开发板系列（标准板和增强板）构建了一个完整的红外通信控制系统，实现了通过红外信号远程控制LED灯状态并在显示屏上实时显示控制信息的功能。发送端使用零知增强板通过YS-IRTM红外编解码模块发送编码后的红外信号。接收端使用零知标准板接收红外信号，解析后控制LED灯开关并在240×240分辨率的ST7789屏幕上显示接收信息。

红外通信模块

>YS-IRTM红外编解码模块：集成了红外发射和接收功能，支持多种红外协议，可通过串口进行控制

>IR Receiver红外接收器：常用的红外接收头，能够接收和解码38kHz载波的红外信号

（2）项目难点及解决方案

问题描述：原始红外编码（如0XFF6897）与YS-IRTM模块所需的编码格式（如A1 F1 00 FF 16）之间存在显著差异，需要建立准确的映射关系。

**解决方案：**通过实验测试确定两种编码格式之间的对应关系，创建映射表并在发送端实现格式转换功能。

一、硬件设计部分

1.1 硬件清单

组件	型号/规格	数量
零知标准板	STM32F103RBT6	1
零知增强板	STM32F407VET6	1
YS-IRTM红外编解码模块	支持串口控制	1
IR Receiver红外接收器	38kHz	1
ST7789显示屏	240×240分辨率	1
LED灯	5mm	1

1.2 接线方案

发送端（零知增强板+YS-IRTM）

零知增强板引脚	YS-IRTM模块引脚	功能
3.3V	VCC	电源
GND	GND	地线
10	TX	数据接收
9	RX	数据发送

接收端（零知标准板）

零知标准板引脚	外设	功能
3.3V	IR Receiver VCC	电源
GND	IR Receiver GND	地线
6	IR Receiver OUT	数据输出
2	LED阳极	LED控制
10	ST7789 CS	片选
9	ST7789 DC	数据/命令
8	ST7789 RST	复位
7	ST7789 BL	背光控制
11	ST7789 SDA	数据输入
13	ST7789 SCL	时钟

1.3 具体连接图

（1）发送端接线

将零知增强板上的11引脚用作软串口的TX、10引脚用作软串口的RX控制YS-IRTM红外编解码器收发数据

（2）接收端接线

1.4 实物接线图

二、软件代码详解

2.1 发送端代码（YS-IRTM）

1.软串口发送编码字节

cpp 复制代码

#include <SoftwareSerial.h>

// 软串口引脚定义
#define SOFT_RX 10
#define SOFT_TX 11

// 解码后的编码映射 - 以字节数组形式存储
byte irCodes[10][5] = {
  {0xA1, 0xF1, 0x00, 0xFF, 0x16}, // 0
  {0xA1, 0xF1, 0x00, 0xFF, 0x0C}, // 1
  {0xA1, 0xF1, 0x00, 0xFF, 0x18}, // 2
  {0xA1, 0xF1, 0x00, 0xFF, 0x5E}, // 3
  {0xA1, 0xF1, 0x00, 0xFF, 0x08}, // 4
  {0xA1, 0xF1, 0x00, 0xFF, 0x1C}, // 5
  {0xA1, 0xF1, 0x00, 0xFF, 0x5A}, // 6
  {0xA1, 0xF1, 0x00, 0xFF, 0x42}, // 7
  {0xA1, 0xF1, 0x00, 0xFF, 0x52}, // 8
  {0xA1, 0xF1, 0x00, 0xFF, 0x4A}  // 9
};

SoftwareSerial mySerial(SOFT_RX, SOFT_TX); // RX, TX

void setup() {
  // 初始化硬件串口
  Serial.begin(9600);
  
  // 初始化软串口
  mySerial.begin(9600);
  
  Serial.println("YS-IRTM Controller Ready");
  Serial.println("Send numbers 0-9 to transmit IR codes");
  Serial.println("Send 'L' to enter learning mode");
}

void loop() {
  // 处理硬件串口输入
  if (Serial.available()) {
    char c = Serial.read();
    
    if (c >= '0' && c <= '9') {
      int num = c - '0';
      
      // 通过软串口发送编码字节
      mySerial.write(irCodes[num], 5);
      
      Serial.print("Sent code for number ");
      Serial.print(num);
      Serial.print(": ");
      for (int i = 0; i < 5; i++) {
        if (irCodes[num][i] < 0x10) Serial.print("0");
        Serial.print(irCodes[num][i], HEX);
        Serial.print(" ");
      }
      Serial.println();
    } 
    else if (c == 'L' || c == 'l') {
      // 进入学习模式
      enterLearningMode();
    }
  }
  
  // 检查是否有学习到的编码
  readLearnedCode();
  
  delay(100);
}

零知IDE串口调试助手发送对应的数字后，将NEC格式的编码数据通过软串口发送到红外发射头。发送字符'L'时进入学习模式读取新的NEC编码

2.读取NEC编码

cpp 复制代码

// 进入学习模式
void enterLearningMode() {
  Serial.println("Entering learning mode...");
  Serial.println("Press a button on your remote control");
}

// 读取学习到的编码
void readLearnedCode() {
  if (mySerial.available() >= 3) {
    byte receivedData[3];
    mySerial.readBytes(receivedData, 3);
    
    Serial.print("Learned code: ");
    for (int i = 0; i < 3; i++) {
      if (receivedData[i] < 0x10) Serial.print("0");
      Serial.print(receivedData[i], HEX);
      Serial.print(" ");
    }
    Serial.println();
  }
}

2.2 接收端代码（IR Receiver）

1.初始化定义

cpp 复制代码

#include <Adafruit_GFX.h>
#include <Adafruit_ST7789.h>
#include <IRremote.h>

// 引脚定义
#define TFT_CS    10
#define TFT_DC    9
#define TFT_RST   8
#define TFT_BL    7  // 背光控制引脚
#define LED_PIN   2  // 板载LED引脚
#define IR_RECV_PIN 6  // 红外接收引脚

// 创建ST7789显示对象
Adafruit_ST7789 tft = Adafruit_ST7789(TFT_CS, TFT_DC, TFT_RST);

// 红外接收对象
IRreceiver irrecv(IR_RECV_PIN);

IRdecode_results decode_result;

// 红外编码映射
unsigned long irCodes[10] = {
  0xFF6897, 0xFF30CF, 0xFF18E7, 0xFF7A85, 0xFF10EF,
  0xFF38C7, 0xFF5AA5, 0xFF42BD, 0XFF4AB5, 0XFF52AD
};

// 当前显示的数字
int currentNumber = -1;

void setup() {
  // 初始化串口通信
  Serial.begin(115200);
  
  // 初始化LED引脚
  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, LOW);
  
  // 初始化ST7789显示屏
  tft.init(240, 240);
  tft.setRotation(1);
  pinMode(TFT_BL, OUTPUT);
  digitalWrite(TFT_BL, HIGH); // 开启背光
  
  // 显示欢迎界面
  tft.fillScreen(ST77XX_BLACK);
  tft.setTextColor(ST77XX_WHITE);
  tft.setTextSize(3);
  tft.setCursor(50, 100);
  tft.print("Ready");
  
  // 初始化红外接收
  irrecv.enableIRIn();
  
  Serial.println("System initialized. Waiting for IR input...");
  Serial.println("Send numbers 0-9 via software serial to transmit IR codes");
}

2.红外接收数据处理

cpp 复制代码

void loop() {
  // 处理红外接收
  if (irrecv.decode(&decode_result)) {
    unsigned long value = decode_result.value;
    Serial.print("Received IR code: 0x");
    Serial.println(value, HEX);
    
    // 检查是否为0-9的数字
    for (int i = 0; i < 10; i++) {
      if (value == irCodes[i]) {
        displayNumber(i);
        
        // 控制LED灯
        if (i == 2) {
          digitalWrite(LED_PIN, HIGH);
          Serial.println("LED turned ON");
        } else if (i == 3) {
          digitalWrite(LED_PIN, LOW);
          Serial.println("LED turned OFF");
        }
        break;
      }
    }
    irrecv.resume(); // 接收下一个值
  }  
  delay(100);
}

// 在屏幕上显示数字
void displayNumber(int number) {
  if (number == currentNumber) return; // 避免重复绘制
  
  currentNumber = number;
  
  tft.fillScreen(ST77XX_BLACK);
  
  // 绘制外圈
  tft.fillRoundRect(5, 5, 235, 235, 30, 0X8410);
  
  // 绘制内圈
  tft.fillRoundRect(15, 15, 215, 215, 30, ST77XX_WHITE);
  
  // 绘制数字
  tft.setTextColor(ST77XX_ORANGE);
  tft.setTextSize(20);
  
  // 根据数字大小调整位置
  int xPos = 75;
  if (number == 1) xPos = 80;
  
  tft.setCursor(xPos, 70);
  tft.print(number);
  
  Serial.print("Displaying number: ");
  Serial.println(number);
}