西门子PLC结构化编程_线性插值算法功能块

文章目录

前言
一、算法原理
二、功能概述
三、程序编写
- [1. 新建数据类型"1_LerpType"](#1. 新建数据类型“1_LerpType”)
- [2. 新建FB块"FB615_Lerp"](#2. 新建FB块“FB615_Lerp”)
- [3. 编程](#3. 编程)
总结

前言

在之前的文章中，我们详细分析了PID算法的原理和推导过程，同时给出了各种各样的PID功能块及仿真块程序。

见文章：

在某些工控场景下，不需要PID这种精确的控制算法，可使用线性插值法等低精度低运算量的算法。本文对线性插值法做简要介绍，并给出程序实现方法。

一、算法原理

线性插值基于两点确定一条直线的思想。已知输入量（温度）在两个边界点（低温度、高温度）对应输出量（频率）的两个边界值（低频率、高频率），则对于任意介于两者之间的输入量，其输出量可通过直线方程计算得出。公式如下：

二、功能概述

分为手动、自动模式；
手动模式下，手动给定输出值，自动模式下，根据线性插值法自动计算出输出值；
手自动无扰切换，当模式切换为手动时，当前时刻的输出值传递给手动设定输出值，以防止手自动切换时产生输出值震荡；
采用分段控制，过程值小于某个值时，以最小输出值输出，过程值大于某个值时，以最大输出值输出，过程值在此之间时，根据线性插值法计算出的输出值输出；
可选择正作用控制器，还是反作用控制器。

三、程序编写

1. 新建数据类型"1_LerpType"

图1

2. 新建FB块"FB615_Lerp"

建立如下引脚变量：

图2

3. 编程

程序段4：

c 复制代码

REGION 手自动无扰切换
    
    IF #Lerp.HMI.HMIManual THEN
        #Lerp.HMI.ManualSetpoint := #Lerp.OutPut.Output;
    END_IF;
    
END_REGION

REGION 模式切换
    
    IF #Lerp.InPut.Running THEN
        IF #Lerp.HMI.Auto_DO THEN
            IF #Lerp.InPut.ProcessValue < #Lerp.HMI.PVLow THEN
                #Lerp.Static.Step := 0;
            END_IF;
            
            IF #Lerp.InPut.ProcessValue > #Lerp.HMI.PVHigh THEN
                #Lerp.Static.Step := 1;
            END_IF;
            
            IF (#Lerp.HMI.PVLow < #Lerp.InPut.ProcessValue) AND (#Lerp.InPut.ProcessValue < #Lerp.HMI.PVHigh) THEN
                #Lerp.Static.Step := 2;
            END_IF;
        ELSIF
            #Lerp.HMI.Manual_DO THEN
            #Lerp.Static.Step := 3;
        END_IF;
    ELSE
        #Lerp.Static.Step := 4;
    END_IF;
    
END_REGION

REGION 输出值计算
    
    CASE #Lerp.Static.Step OF
        0:
            IF #Lerp.HMI.Direction THEN
                #Lerp.Static.OutputTemp := #Lerp.HMI.LowSetpoint;
            ELSE
                #Lerp.Static.OutputTemp := #Lerp.HMI.HighSetpoint;
            END_IF;
        1:
            IF #Lerp.HMI.Direction THEN
                #Lerp.Static.OutputTemp := #Lerp.HMI.HighSetpoint;
            ELSE
                #Lerp.Static.OutputTemp := #Lerp.HMI.LowSetpoint;
            END_IF;
        2:
            #Lerp.Static.PV_Percent := (#Lerp.InPut.ProcessValue - #Lerp.HMI.PVLow) / (#Lerp.HMI.PVHigh - #Lerp.HMI.PVLow);
            IF #Lerp.HMI.Direction THEN
                #Lerp.Static.OutputTemp := #Lerp.HMI.LowSetpoint + #Lerp.Static.PV_Percent * (#Lerp.HMI.HighSetpoint - #Lerp.HMI.LowSetpoint);
            ELSE
                #Lerp.Static.OutputTemp := #Lerp.HMI.HighSetpoint - #Lerp.Static.PV_Percent * (#Lerp.HMI.HighSetpoint - #Lerp.HMI.LowSetpoint);
            END_IF;
        3:
            #Lerp.Static.OutputTemp := #Lerp.HMI.ManualSetpoint;
        4:
            #Lerp.Static.OutputTemp := #Lerp.OutPut.Output;
    END_CASE;
    
    IF #Lerp.HMI.Enable THEN
        // 频率输出限幅
        #Lerp.OutPut.Output := LIMIT(MN := #Lerp.Static.OutputMIN, IN := #Lerp.Static.OutputTemp, MX := #Lerp.Static.OutputMAX);
        
        // 频率输出转换
        "FC607_AnalogOutPutConver"(AO_IN := #Lerp.OutPut.Output,
                                   IN_MAX := #Lerp.Static.OutputMAX,
                                   IN_MIN := #Lerp.Static.OutputMIN,
                                   OUT_MAX := 27648,
                                   OUT_MIN := 0,
                                   AO_OUT => #Lerp.OutPut.Output_PER);
    END_IF;
    
END_REGION

REGION 按钮自复位
    
    #Lerp.HMI.HMIManual := #Lerp.HMI.HMIManual AND NOT #Lerp.Static.ReSet[0];
    #Lerp.HMI.HMIAuto := #Lerp.HMI.HMIAuto AND NOT #Lerp.Static.ReSet[1];
    
    #Lerp.Static.ReSet[0] := #Lerp.HMI.HMIManual;
    #Lerp.Static.ReSet[1] := #Lerp.HMI.HMIAuto;
    
END_REGION

其中，"FC607_AnalogOutPutConver"是指调用FC块"FC607_AnalogOutPutConver"，该程序块可将工程量转换为模拟量。参考文章《西门子PLC常用底层逻辑块分享_模拟量写入》。

总结

本文详细阐述了线性插值算法在西门子博途编程平台中的程序实现过程。在实际工业控制场景中，可代替PID用于简单的开环控制环节，以降低程序的复杂度。